0

想做以下从 SKI 表达式到 lambda 表达式的反向转换：

L[I] = λx.x

L[K] = λx.λy.x

L[S] = λx.λy.λz.(x z (y z))

L[(E₁ E₂)] = (L[E₁] L[E₂])

转换不需要涉及任何β-减少。但我仍然想做一个特殊的 beta-reduction。每当有线性 redex 或单位 redex 时：

 (λx.E₁)E₂      x occurs at most once in E₁

我想把它减少到：

 E₁[x/E₂]

从某种意义上说，这似乎是一种安全的减少，它不会使 redex 变得更大，它只会移动 E₂ 的位置，甚至在 x 不出现的情况下消除 E₂。分别进行重命名。例子：

 L[S(S(K(S(KS)K))S)(KK)] = λx.λy.λz.xzy

周围有任何Prolog实现吗？

4

2 回答 2

0

这是一个基于 deBruijn 索引的实现，并且基于 Prolog 的答案here。第一部分，将 L[_] 从维基百科翻译成 deBruijn 索引给出：

lambda(P*Q, W) :-
   lambda(P, R),
   lambda(Q, S),
   simplify(R, S, W).
lambda('I', b(0)).
lambda('K', b(b(1))).
lambda('S', b(b(b(2*0*(1*0))))).

线性化简中的新谓词是 simple/2、subst2/4、notin/2 和 oncein/2。shift/4 与此处的 Prolog 答案完全相同。与 subst/4 相比，谓词 subst2/4 调用 simple/2 来构建应用程序术语：

simplify(b(R), _, S) :- notin(R, 0), !,
   shift(R, 0, -1, S).
simplify(b(R), S, T) :- oncein(R, 0), !,
   subst2(R, 0, S, T).
simplify(R, S, R*S).

subst2(P*Q, J, D, W) :- !,
   subst2(P, J, D, R),
   subst2(Q, J, D, S),
   simplify(R, S, W).
subst2(b(P), J, D, b(R)) :- !,
   K is J+1,
   subst2(P, K, D, R).
subst2(J, K, _, J) :- integer(J), J < K, !.
subst2(0, 0, D, D) :- !.
subst2(J, J, D, R) :- integer(J), !,
   shift(D, 0, J, R).
subst2(J, _, _, K) :- integer(J), !, K is J-1.
subst2(I, _, _, I).

谓词 notin/2 和 oncein/2 将“最多一次”分为“不”和“恰好一次”：

notin(P*Q, J) :- !,
   notin(P, J),
   notin(Q, J).
notin(b(P), J) :- !,
   K is J+1,
   notin(P, K).
notin(J, K) :- integer(J), !,
   J =\= K.
notin(_, _).

oncein(P*Q, J) :-
   notin(P, J), !,
   oncein(Q, J).
oncein(P*Q, J) :- !,
   oncein(P, J),
   notin(Q, J).
oncein(b(P), J) :- !,
   K is J+1,
   oncein(P, K).
oncein(J, J).

这是解决的问题：

?- lambda('S'*('S'*('K'*('S'*('K'*'S')*'K'))*'S')*('K'*'K'), X).
X = b(b(b(2*0*1)))

该示例与此处的括号抽象不完全相反：

?- unlambda(b(b(b(2*0*1))), X).
X = 'S'*('S'*('K'*'S')*('S'*('K'*'K')*'S'))*('K'*'K')
于 2020-12-19T14:59:45.520 回答
0

将规范相当直接地转换为具有逻辑变量的表示：

combinator_lambda(i, lambda(X, X)).
combinator_lambda(k, lambda(X, lambda(_Y, X))).
combinator_lambda(s, lambda(X, lambda(Y, lambda(Z,
                        apply(apply(X, Z), apply(Y, Z)))))).
combinator_lambda(C1 * C2, Lambda) :-
    combinator_lambda(C1, L1),
    combinator_lambda(C2, L2),
    simplify(apply(L1, L2), Lambda).
    
simplify(Term, Simple) :-
    (   nonvar(Term),
        Term = apply(X, Y)
    ->  simplify(X, SimpleX),
        simplify(Y, SimpleY),
        (   nonvar(SimpleX),
            SimpleX = lambda(V, Exp),
            term_atmostonce(Exp, V)
        ->  apply(SimpleX, SimpleY, XY),
            simplify(XY, Simple)
        ;   Simple = apply(SimpleX, SimpleY) )
    ;   nonvar(Term),
        Term = lambda(V, Exp)
    ->  simplify(Exp, SimpleExp),
        Simple = lambda(V, SimpleExp)
    ;   Simple = Term ).
    
term_atmostonce(Term, NoOccurrence) :-
    term_variables(Term, Variables),
    forall(member(Var, Variables), Var \== NoOccurrence),
    !.
term_atmostonce(Term, Singleton) :-
    term_singletons(Term, Singletons),
    member(Var, Singletons),
    Var == Singleton,
    !.
    
apply(lambda(V, E), V, E).

（term_singletons是一个 SWI-Prolog 实用程序。）

?- combinator_lambda(s*(s*(k*(s*(k*s)*k))*s)*(k*k), Lambda), numbervars(Lambda). 
Lambda = lambda(A, lambda(B, lambda(C, apply(apply(A, C), B)))).
于 2020-12-19T21:49:14.530 回答