1

我有带 rgb 液晶屏的 Arduino uno。一个特定功能中的按钮有一种非常奇怪的行为。

该函数称为是/否。它在屏幕上显示一条消息（工作），用户可以使用上/下/左/右按钮选择回答是/否，并通过按下选择按钮批准答案。

功能如下：

bool yesno(String message)
{
  //Serial.println("asking yesno question " + message);
  bool answer = false;
  bool answerSelected = false;
  setColor('r');
  setText(message+'?', "no");
  while (!answerSelected)
  {
    uint8_t buttons = lcd.readButtons();
    if (buttons){
      if (buttons &(BUTTON_UP || BUTTON_DOWN || BUTTON_RIGHT || BUTTON_LEFT)) {
        if (answer) {
          answer = false;
          setColor('r');
          setText(message+'?', "no");
          Serial.println(answer);
        }
        else {
         answer = true;
         setColor('g');
         setText(message+'?', "yes");
         Serial.println(answer);
        }
      }
      else if (buttons & BUTTON_SELECT) {
        setColor('w');
        answerSelected = true;
        Serial.println("selected ");
        Serial.println(answer);
        return answer;
      }
    }
    delay(50);
  }
}

出于某种原因，当按下左/右/上/下时，没有任何反应。按下选择时，它会执行上/下/左/右功能

相反，使用if (buttons &&(BUTTON_UP || BUTTON_DOWN || BUTTON_RIGHT || BUTTON_LEFT))左/右/上/下按钮按预期工作，但按钮选择仍充当其他按钮

菜单的类似代码按预期工作：

void InitializeMenu()
{
  // initialize
  Serial.println("entering menu");
  setColor('w');
  while (!exitMenu)
  {
    if (menuItem != selectedItem)
    {
      Serial.println("switching menu to: "+menuItems[menuItem]);
      setText("Menue", menuItems[menuItem]);
      selectedItem = menuItem;
    }
    uint8_t buttons = lcd.readButtons();
    if (buttons & BUTTON_UP) {
      menuItem--;
      Serial.println("menu up");
      Serial.println(menuItem);
      Serial.println(menuSize);
      if (menuItem < 0) 
      {
        menuItem = menuSize;
        Serial.println("start of menu going to end");
      } 
    }
    if (buttons & BUTTON_DOWN) {
      menuItem++;
      Serial.println("menu down");
      Serial.println(menuItem);
      Serial.println(menuSize);
      if (menuItem > menuSize) {
        menuItem = 0;
        Serial.println("end of menu going to start");
       }
     }
     if (buttons & BUTTON_SELECT) {
      Serial.println("enter");
       if (menuItem == menuSize) exitMenu = true;
     }
     delay(50);
  }
}

由于 arduino uno 上的空间非常有限，我想让代码尽可能简短。

4

1 回答 1

0 
BUTTON_UP || BUTTON_DOWN || BUTTON_RIGHT || BUTTON_LEFT

没有做你期望它做的事情。||是合乎逻辑 or的，整个表达式的计算结果为true。要获得位掩码，请将其更改为按位 or( |)：

BUTTON_UP | BUTTON_DOWN | BUTTON_RIGHT | BUTTON_LEFT
于 2020-11-16T00:00:45.977 回答