xml - 在 XSLT 中用逗号作为小数分隔符对数字求和？

Question

我有一个 XML 文件，其中的数字以逗号分隔

<foo>
  <bar val="1,23"/>
  <bar val="4,56"/>
  <bar val="7,89"/>
</foo>

我想对/foo/bar/@valXSLT 中的值求和，但我有点卡住了格式。有谁知道正确的语法是什么？

Answer 1

我猜，"val"属性中指定的值是一个带有逗号而不是小数点的数字。

几种解决方案是可能的：

一、XSLT 1.0

这种转变：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:ext="http://exslt.org/common"
 >
  <xsl:output method="text"/>
<!--                                           -->  
    <xsl:template match="foo">
      <xsl:variable name="vrtfBars">
        <xsl:for-each select="bar">
          <bar val="{translate(@val, ',', '.')}"/>
        </xsl:for-each>
      </xsl:variable>
<!--                                           -->
      <xsl:value-of select=
       "sum(ext:node-set($vrtfBars)/*/@val)"/>
    </xsl:template>
</xsl:stylesheet>

当应用于最初提供的 XML 文档时：

<foo>
    <bar val="1,23"/>
    <bar val="4,56"/>
    <bar val="7,89"/>
</foo>

产生想要的结果：

13.68

二、XSLT 2.0

这种转变：

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema"
 exclude-result-prefixes="f xs"
 >
 <xsl:output method="text"/>
<!--                                           -->
 <xsl:template match="foo">
  <xsl:sequence select=
   "sum(bar/@val/number(translate(., ',', '.')))" 
   />
 </xsl:template>
</xsl:stylesheet>

当应用于同一个 XML 文档时，会产生相同的正确结果：

13.68

三、FXSL 2.x

这种转变：

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema"
 xmlns:f="http://fxsl.sf.net/"
 xmlns:my="my:fun"
 exclude-result-prefixes="my f xs"
 >
   <xsl:import href="../f/func-transform-and-sum.xsl"/>
<!--                                           -->
 <xsl:output method="text"/>
<!--                                           -->
 <xsl:template match="foo">
  <xsl:sequence select=
   "sum(
        f:transform-and-sum(my:makeNum(), bar/@val )
        )" 
   />
 </xsl:template>
<!--                                           -->
 <xsl:function name="my:makeNum" as="xs:double">
   <xsl:param name="psNum" as="xs:string"/>
<!--                                           -->
   <xsl:sequence select="number(translate($psNum, ',', '.'))"/>
 </xsl:function>
<!--                                           -->
 <xsl:function name="my:makeNum" as="element()">
   <my:makeNum/>
 </xsl:function>
<!--                                           -->
 <xsl:template match="my:makeNum" as="xs:double" mode="f:FXSL">
   <xsl:param name="arg1" as="xs:string"/>
<!--                                           -->
   <xsl:sequence select="my:makeNum($arg1)"/>
 </xsl:template>
</xsl:stylesheet>

当应用于同一个 XML 文档时，会产生相同的正确结果：

13.68

最后一种解决方案更灵活，可以在求和之前需要对值进行更复杂的转换时成功使用。

Answer 2

假设与 Dimitre 相同，您的意思是逗号用作小数分隔符，而不是用作整数列表的分隔符。

没有 EXSLT 节点集扩展的纯 XSLT 1.0：

<xsl:template match="foo">
  <xsl:call-template name="sum">
    <xsl:with-param name="node" select="bar[1]"/>
  </xsl:call-template>
</xsl:template>

<xsl:template name="sum">
  <xsl:param name="node"/>
  <xsl:param name="sum" select="0"/>
  <xsl:choose>
    <xsl:when test="$node">
      <xsl:call-template name="sum">
        <xsl:with-param name="node" select="$node/following-sibling::bar[1]"/>
        <xsl:with-param name="sum" select="$sum + translate($node/@val, ',', '.')"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="$sum"/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

Answer 3

我觉得我说了很多，但它需要重复：XML 的全部意义在于它以易于解析的形式提供数据。包含无法解析为 XML 的数据的 XML 没有意义；如果可能的话，您应该修复您的 XML 或使用不同的格式。