2

就像我想改变的练习一样：

(alist "foo" 1 "bar" 2 "baz" 3)

进入

(("foo" . 1) ("bar" . 2) ("baz" . 3))

这可能与语法规则吗？

我的尝试：

(define-syntax alist
  (syntax-rules ()
     ((_ a b) (cons a b))
     ((_ x y ...)
      (list (alist x y) ...))))

它扩展成的问题：

(("foo" . 2) ("foo" . "bar") ("foo" . 4) ("foo" . "baz") ("foo" . 6))

语法规则可以使用宏 alist 吗？它应该是什么样子？

编辑：

又一次尝试

(define-syntax alist
  (syntax-rules ()
     ((_ a b) (cons a b))
     ((_ x y z ...)
      (list (alist x y) (alist z ...)))))

它返回(("foo" . 2) (("bar" . 4) ("baz" . 6)))。

4

2 回答 2

2

我已经弄清楚了：

(define-syntax alist
  (syntax-rules ()
     ((_) ())
     ((_ a b) (list (cons a b)))
     ((_ x y z ...)
      (apply list (cons x y) (alist z ...)))))

和简化版：

(define-syntax alist
  (syntax-rules ()
     ((_) ())
     ((_ a b) (list (cons a b)))
     ((_ x y z ...)
      (cons (cons x y) (alist z ...)))))
于 2020-11-03T08:56:02.173 回答
1

如果它只是文字（如"foo"and 2），你可以这样做：

#!r6rs
(import (rnrs))

(define-syntax alist
  (syntax-rules (alist-builder)
    ((_ alist-builder () (results ...)) 
     '(results ...))
    ((_ alist-builder (a) . rest) 
     (raise 'bad-alist))
    ((_ alist-builder (a b rest ...) (results ...))
     (alist alist-builder (rest ...) (results ... (a . b))))
    ((_ a ...) (alist alist-builder (a ...) ()))))

(alist)         ; ==> ()
(alist "a" 2)   ; ==> (("a" . 2))
(alist a 3 b 4) ; ==> ((a . 3) (b . 4))
(alist a)       ; ==> uncaught exception: bad-alist

当然，您不允许对其进行变异，因为(alist a b c d)与字面上的书写相同'((a . b) (c . d))，您不允许变异。

此外，如果您将 alistalist-builder作为第一个键，则内部结构会泄漏。您可以通过拆分内部定义来解决此问题，并且可以通过将其隐藏在库中并仅导出来隐藏它alist

于 2020-11-03T23:14:20.417 回答