0

我有一个 ByVal 代码来清除表格内特定范围的内容，它可以工作。但是如果范围值（内容）发生变化，我需要为指令执行添加一个条件，而不是如果我只将光标放在它上面。

另外，有人知道如何在 VBA 中引用表列吗？现在我使用的是估计范围“C1:C999”，但我想使用他的名字“A_[OPERATION]”。

这是代码：

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

   If Not Application.Intersect(Range("C1:C999"), Range(Target.Address)) Is Nothing Then
    
       Range(Selection, Selection.End(xlToRight)).ClearContents

   End If

End Sub
4

3 回答 3

1

您可以改用更改事件。

这是文档的链接： https ://docs.microsoft.com/en-us/office/vba/api/excel.worksheet.change

或者，您可以将目标单元格的值保存在变量中，并在执行清除内容之前检查该值是否已更改。

对于您的第二个问题，您可能应该在单独的帖子中询问它。

于 2020-11-01T00:59:06.207 回答
0

工作表更改

  • 调整表名（tName）和表头（列）名（hName）。
  • 我已经对其进行了调整，以清除列后单元格中的内容。
  • 如果您确实也需要清除该列的内容，请替换cel.Offset(, 1)为cel.
  • 在表格中，如果手动或通过 VBA 更改了列中的值，当前设置将自动清除指定列右侧的所有单元格的内容。如果列包含公式，这将不起作用。也支持非连续删除。

编码

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    
    Const ProcName As String = "Worksheet_Change"
    On Error GoTo clearError
    
    Const tName As String = "A_"
    Const hName As String = "OPERATION"
    
    Dim rng As Range
    Set rng = Range(tName & "[" & hName & "]")
    Set rng = Intersect(rng, Target)
    If rng Is Nothing Then GoTo ProcExit
    
    Application.EnableEvents = False
    
    With ListObjects(tName).HeaderRowRange
        Dim LastColumn As Long
        LastColumn = .Columns(.Columns.Count).Column
    End With
    Dim cel As Range
    For Each rng In rng.Areas
        For Each cel In rng.Cells
            With cel.Offset(, 1)
                .Resize(, LastColumn - .Column + 1).ClearContents
            End With
        Next cel
    Next rng

CleanExit:
    Application.EnableEvents = True
    GoTo ProcExit

clearError:
    Debug.Print "'" & ProcName & "': " & vbLf _
              & "    " & "Run-time error '" & Err.Number & "':" & vbLf _
              & "        " & Err.Description
    On Error GoTo 0
    GoTo CleanExit

ProcExit:

End Sub
于 2020-11-01T02:50:52.927 回答
0

单元格值的变化由Worksheet_Change事件句柄捕获。

但是，即使是错误更改，此句柄也会触发。例如，如果更改前的单元格值为“A”，而用户刚刚在该单元格中再次输入“A”，则无论如何都会触发更改事件过程。

为了避免这种情况，我们可以一起使用Worksheet_Change和Worksheet_SelectionChange。

使用Worksheet_SelectionChange，我们在某处记录旧值，例如 a Name。然后使用Worksheet_Change，我们可以将用户输入的内容与 进行比较，Name以查看是否进行了真正的更改。

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Dim Nm As Name: Set Nm = ActiveWorkbook.Names("OldValue")
    If Target.Count = 1 Then
        'This only record one old cell value.
        'To record multiple cells old value, use a hidden Worksheet to do so instead of a Name.
        Nm.Comment = Target.Value2
    else
        Nm.Comment = Target.Value2(1, 1)
    End If
End Sub

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim Nm As Name: Set Nm = ActiveWorkbook.Names("OldValue")
    If Target.Value2 <> Nm.Comment Then
        Debug.Print "True change"
    Else
        Debug.Print "False change"
    End If
End Sub

您可以通过对象访问表的方法和属性listobject。以下是如何执行此操作的示例。

Sub Example()
    Dim lo As ListObject
    Dim lc As ListColumn
    Set lo = Range("Table1").ListObject
    Set lc = lo.ListColumns("Column2")
End Sub

也就是说，对于您的情况，它将是Range("A_").ListObject.ListColumns("OPERATION").DataBodyRange.

于 2020-11-01T05:17:27.300 回答