0

我有一个可以在 Google 日历中正确生成事件的应用程序，现在我希望能够通过为其生成 Google 会议链接来修改任何事件。理想情况下，我想生成没有任何日历事件的 Google 会议链接，但据我研究，目前唯一的方法是将其创建为 Google 日历事件的一部分。

我已按照https://developers.google.com/calendar/create-events?hl=en_US#java中的步骤进行操作，并提出了以下功能：

(defn add-meet-link-to-calendar-event
  "Adds a meet link to a calendar event."
  [google-ctx calendarId input-event]
  (if input-event
    (let [calendar-service (build-calendar-service google-ctx)
          events           (doto (.events ^Calendar calendar-service)
                             assert)
          conf-req-data (doto (CreateConferenceRequest.)
                          (.setRequestId (generate-random-string))
                          (.setConferenceSolutionKey (.setType (ConferenceSolutionKey.)
                                                               "hangoutsMeet")))
          conference-data (doto (ConferenceData.)
                            (.setCreateRequest conf-req-data)
                            )
          event (doto input-event
                        (.setConferenceData conference-data)
                        (.set "conferenceDataVersion" 1)
                        (.set "sendNotifications" true)
                        )
          eventId (get event "id")
          adding-link   (.patch events calendarId eventId event)]
      (prn "Before executing at add-meet-link-to-calendar-event" calendarId eventId event events)
      (.execute adding-link))))

作为此函数的输入事件的一部分，我将从另一个函数传递以下输出，该函数从 Google 日历中检索事件对象：

{"attendees" [{"email" "jjj@company.com", 
"responseStatus" "needsAction"} 
{"email" "main@company.com", 
"organizer" true, 
"responseStatus" "accepted", 
"self" true}], 
"created" #object[com.google.api.client.util.DateTime 0x686d6e12 "2020-10-26T15:27:49.000Z"], 
"creator" {"email" "main@company.com", 
"self" true}, 
"end" {"dateTime" #object[com.google.api.client.util.DateTime 0x5a909950 "2020-10-24T22:30:00.000+02:00"]}, 
"etag" "\"3207454201190000\"", 
"htmlLink" "https://www.google.com/calendar/event?eid=M25wb2RtbnNsNWN2N3E3MGVsc2RvYTQwc2ogbmFpaGFAdWJpa2FyZSAAAA", 
"iCalUID" "3npodmnsl5cv7q70elsdoaAAAA@google.com", 
"id" "3npodmnsl5cv7q70elsdoaAAAA", 
"kind" "calendar#event", 
"organizer" {"email" "main@company.com", "self" true}, 
"reminders" {"useDefault" true}, 
"sequence" 0, 
"start" {"dateTime" #object[com.google.api.client.util.DateTime 0x7bcdfc0e "2020-10-24T22:00:00.000+02:00"]}, 
"status" "confirmed", 
"summary" "Another meet test", 
"updated" #object[com.google.api.client.util.DateTime 0xd4057 "2020-10-26T15:45:00.595Z"]}

我已经测试过summary可以更新类似的值，因此patch调用似乎有效。但即使添加conferenceDataVersion和conferenceData似乎也不会改变事件。

如果我手动更改 Google 日历中的事件，我可以看到会议详细信息已添加到事件中。

4

2 回答 2

1

根据日历 API 事件资源文档：

hangoutLink> 与此活动相关的 Google+ 视频群聊的绝对链接。只读.

所以本质上，你不能通过hangoutLinkCalendar API来改变。

您可以在此处在 Google 问题跟踪器上为问题加注星标 ★ 。

更新

您可以hangoutLink通过发出关注请求向事件添加一个，但是，您不能更改链接，因为它是自动分配的：

要求

PATCH https://www.googleapis.com/calendar/v3/calendars/calendarId/events/eventId?conferenceDataVersion=1

身体

{
  "conferenceData": {
    "createRequest": {
      "conferenceSolutionKey": {
        "type": "eventNamedHangout"
      },
      "requestId": "SOME_STRING"
    }
  }
}

参考

于 2020-10-27T10:14:47.900 回答
0

这就是我最终设法修复它的方法，这要归功于@ale13 提供的链接中的信息（Google Calendar API 中的 Meet）：

(defn add-meet-link-to-calendar-event
  "Adds a meet link to a calendar event."
  [google-ctx calendarId eventId]
  (if eventId
    (let [calendar-service (build-calendar-service google-ctx)
          events           (doto (.events ^Calendar calendar-service)
                             assert)
          conf-req-data (doto (CreateConferenceRequest.)
                          (.setRequestId (generate-random-string))
                          (.setConferenceSolutionKey (.setType (ConferenceSolutionKey.)
                                                               "hangoutsMeet")))
          conference-data (doto (ConferenceData.)
                            (.setCreateRequest conf-req-data)
                            )
          event (doto (Event.)
                        (.setConferenceData conference-data))
          adding-link   (.patch events calendarId eventId event)
          set-data-conf (.setConferenceDataVersion adding-link (int 1))
          ]
      (prn "Before executing" calendarId event)
      (.execute set-data-conf))))

所以这里的关键是该conferenceDataVersion值不必作为会议数据主体的一部分提供。它是一个必须在结果setConferenceDataVersion上调用的 setter ( ) 。patch

通过此更改，将接收到完整的事件数据，可以从中提取与会议相关的不同链接。

于 2020-10-27T13:03:41.413 回答