view - SQL Server 2005 Express - 生成脚本以基于关系表创建 VIEW？

Question

SQL Server 2005 Express 中有没有一种方法可以生成一个脚本，该脚本将基于表的主/外键关系创建一个视图？

我有多个包含数千个表的数据库，查看“表依赖项”并尝试在查询窗口中加入数据非常耗时。

谢谢

Answer 1

此查询返回表的创建语句，但您必须首先注意：1.仅适用于 1 列外键引用 2.尚未针对 sql server express 2005 进行测试，但适用于 Sql server 2005

create function dbo.func59C217D64BC54EA0B841BF1AB43D9398(@table1 nvarchar(1000), @table2 nvarchar(1000))
returns nvarchar(max)
as
begin
declare @sql nvarchar(max)
set @sql = ''
select @sql = @sql + dr + '.[' +cc +'] AS ['+ cc+ ISNULL(rr,'') + '],'
from (
select column_name cc,
dr = case when table_schema + '.' +table_name = @table1 then 'a' else 'b' end,
cast(NULLIF(row_number() over (partition by column_name order by table_name),1) as nvarchar) rr
 from INFORMATION_SCHEMA.COLUMNS where table_schema + '.' +table_name in
(@table1,@table2)
) i

return substring(@sql,1,len(@sql) - 1)
end


GO
select cast(
'CREATE VIEW ['+r.CONSTRAINT_SCHEMA+'].[vw' +cp.TABLE_NAME+cf.TABLE_NAME+ ']
AS SELECT '+dbo.func59C217D64BC54EA0B841BF1AB43D9398(cp.TABLE_SCHEMA+'.' +cp.TABLE_NAME,cf.TABLE_SCHEMA+ '.' +cf.TABLE_NAME)+' FROM ['+cp.TABLE_SCHEMA+'].['+cp.TABLE_NAME+'] AS a
JOIN ['+cf.TABLE_SCHEMA+'].['+cf.TABLE_NAME +'] AS b
ON a.['+cp.COLUMN_NAME+'] = b.['+cf.COLUMN_NAME +']' as ntext) as sql
 from INFORMATION_SCHEMA.REFERENTIAL_CONSTRAINTS r
 JOIN INFORMATION_SCHEMA.CONSTRAINT_COLUMN_USAGE cf ON r.CONSTRAINT_NAME = cf.CONSTRAINT_NAME 
 JOIN INFORMATION_SCHEMA.CONSTRAINT_COLUMN_USAGE cp ON r.UNIQUE_CONSTRAINT_NAME = cP.CONSTRAINT_NAME 


GO
DROP function dbo.func59C217D64BC54EA0B841BF1AB43D9398

希望我有帮助，或者至少让你开始