1

有一个图，它的每个节点都包含属性communityId来指示该节点属于哪个社区。节点通过关系连接，LINK关系包含weight属性。

我想要的是把同一个社区的那些节点合并成一个大节点。这些大节点（又名社区）之间的链接必须合理地合成/组合：链接的weight属性必须根据每个社区中相互连接的各个节点进行累加。必须尊重链接的方向。

在结果图中，我只会看到连接的社区节点。

最接近的函数是Merge Nodes函数apoc.refactor.mergeNodes()。但是，我对结果不满意，因为：

  • 问题一：结果社区节点有自链接。
  • 问题 2：链接的权重没有合并，尽管文档是这样说的。

问题 1 可以通过再编写一个 Cypher 来删除自链接来解决。但是问题 2 只能通过对 Graph 的低级访问来解决（mergeNodes()如上）。

是否有任何优雅的方法可以一次性获得我想要的图表（社区节点）？或者至少，必须以某种方式解决问题 2。

再现性

图形：

CREATE (a:User {name: "A", communityId: 2}), (b:User {name: "B", communityId: 2}), (c:User {name: "C", communityId: 2}), (x:User {name: "X", communityId: 1}), (y:User {name: "Y", communityId: 1}), (z:User {name: "Z", communityId: 1}), (w:User {name: "W", communityId: 1}), (a)-[:LINK {weight: 1}]->(b), (b)-[:LINK {weight: 1}]->(c), (c)-[:LINK {weight: 1}]->(a), (b)-[:LINK {weight: 1}]->(z), (z)-[:LINK {weight: 1}]->(x), (z)-[:LINK {weight: 1}]->(w), (w)-[:LINK {weight: 1}]->(y), (y)-[:LINK {weight: 1}]->(x), (b)-[:LINK {weight: 1}]->(w)

在此处输入图像描述

暗号：

MATCH (n:User)
WITH n.communityId AS communityId, COLLECT(n) AS nodes
CALL apoc.refactor.mergeNodes(nodes, {
    properties: {
        name: 'combine',
        communityId: 'discard',
        weight: 'combine'
    },
    mergeRels: true
})
YIELD node
RETURN node

在此处输入图像描述

系统要求

  • 视窗 8.1 x64
  • Neo4j 桌面 v1.3.4（引擎 v4.1.1。）
  • APOC v4.1.0.2
  • 图数据科学库 v1.3.2
4

1 回答 1

0

我不太清楚为什么 APOC 不合并您示例中的关系。但是，这里有一个 Cypher 查询可以帮助您入门：

MATCH (n:User)-[r]->(v:User)
WHERE n.communityId <> v.communityId  // discard self loop
WITH n.communityId as comId1, v.communityId as comId2, sum(r.weight) as w
MERGE (su1:SuperUser {communityId: comId1})  // create or get merged node for n.communityId
MERGE (su2:SuperUser {communityId: comId2})  // create or get node for v.communityId
MERGE (su1)-[r:SUPER_LINK]->(su2)
ON CREATE SET r.weight = w  // set relationship weight when it is created
RETURN su1, su2, r

它创建了以下节点和关系：

超级节点和超级链接

于 2020-09-12T07:28:46.013 回答