2

这是对我之前发布的一个问题的一点后续。我的基本问题是使用Gambit Scheme构建应用程序。

虽然上述问题中建议的解决方案有效，但它有点麻烦，所以我决定尝试将 Gambit Scheme 作为自定义编译器/语言添加到 CMake。按照这个问题中的建议，我创建了以下文件：

cmake/CMakeDetermineGambitCompiler.cmake：

# Find the compiler
find_program(
    CMAKE_Gambit_COMPILER 
        NAMES "gambitc"
        HINTS "${CMAKE_SOURCE_DIR}"
        DOC "Gambit Scheme compiler" 
)

mark_as_advanced( CMAKE_Gambit_COMPILER )

set( CMAKE_Gambit_SOURCE_FILE_EXTENSIONS scm;six )
# Remember this as a potential error
set( CMAKE_Gambit_OUTPUT_EXTENSION .c )
set( CMAKE_Gambit_COMPILER_ENV_VAR "" )

# Configure variables set in this file for fast reload later on
configure_file( ${CMAKE_CURRENT_LIST_DIR}/CMakeGambitCompiler.cmake.in
                ${CMAKE_PLATFORM_INFO_DIR}/CMakeGambitCompiler.cmake )

cmake/CMakeGambitInformation.cmake：

# This file sets the basic flags for the GAMBIT compiler

# Generate the C files
set( CMAKE_Gambit_COMPILE_OBJECT
    "<CMAKE_Gambit_COMPILER> -o <OBJECT> -c <SOURCE>"
)

# Build a executable 
set( CMAKE_Gambit_LINK_EXECUTABLE 
    "<CMAKE_Gambit_COMPILER> -o <TARGET> -exe <OBJECTS>"
)

set( CMAKE_Gambit_INFORMATION_LOADED 1 )

cmake/CMakeGambitCompiler.cmake.in：

set( CMAKE_Gambit_COMPILER "@CMAKE_Gambit_COMPILER@" )
set( CMAKE_Gambit_COMPILER_LOADED 1 )
set( CMAKE_Gambit_SOURCE_FILE_EXTENSIONS @CMAKE_Gambit_SOURCE_FILE_EXTENSIONS@ )
set( CMAKE_Gambit_OUTPUT_EXTENSION @CMAKE_Gambit_OUTPUT_EXTENSION@ )
set( CMAKE_Gambit_COMPILER_ENV_VAR "@CMAKE_Gambit_COMPILER_ENV_VAR@" )

cmake/CMakeTestGambitCompiler.cmake：

# For now do nothing
set( CMAKE_Gambit_COMPILER_WORKS 1 CACHE INTERNAL "" )

然后，在我的项目根目录中，我还有两个文件：

CMakeTexts.txt：

cmake_minimum_required( VERSION 3.10...3.18 )

if( ${CMAKE_VERSION} VERSION_LESS 3.12 )
    cmake_policy( VERSION ${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} )
endif()

# Give the project a name
project( cmake-scheme-template NONE )

# Build simple Gambit Scheme program
list( APPEND CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/cmake")
enable_language( Gambit )
add_executable( ${PROJECT_NAME} main.scm )

要构建的实际代码main.scm：

;;; Simple Scheme example
(begin (write "Hello, Schemer!")
       (newline))

给出以下结构：

project_root/
    cmake/
        CMakeDetermineGambitCompiler.cmake
        CMakeGambitCompiler.cmake.in
        CMakeGambitInformation.cmake
        CMakeTestGambitCompiler.cmake
    CMakeLists.txt
    main.scm

虽然这适用于单个文件，但一旦我添加了另一个源文件，我需要 Gambit 首先为从 Scheme 源生成的所有 C 文件创建一个链接文件。这是一个简单的例子：

假设我添加了第二个文件factmodule.scm：

;;; This is a simple Scheme module that provides a functions that will 
;;; calculate the factorial of a number n
(define fact
  (lambda (n)
    (if (zero? n)
        1
        (* n (fact (- n 1))))))

并更新main.scm：

(begin (write "Hello, Schemer!")
       (newline)
       (write "10! = ")
       (write (number->string (fact 10)))
       (newline))

为了“手动”构建这个，我执行以下操作：

$ gambitc -c factmodule.scm main.scm                      # generate C files from Scheme
$ gambitc -o link_file.c -link factmodule.c main.c        # generate a link file
$ gambitc -obj factmodule.c main.c link_file.c            # compile the C files in object files
$ gcc -o myexec -factmodule.o main.o link_file.o -lgambit # link the final executable

我的问题是第二步，创建链接文件。理想情况下，我想在cmake/CMakeGambitInformation.cmake中添加如下内容：

# Generate the C, link, and object files
set( CMAKE_Gambit_COMPILE_OBJECT
    "<CMAKE_Gambit_COMPILER> -o <OBJECT> -c <SOURCE>"        # generate C files
    "<CMAKE_Gambit_COMPILER> -o link_file.c -link <OBJECTS>" # generate link file
    "<CMAKE_Gambit_COMPILER> -obj <OBJECTS>"                 # compile C and link files
)

但这有两个问题。一、<OBJECTS>保存生成的C文件；据我了解，给出的命令CMAKE_Gambit_COMPILE_OBJECT是在每个源文件基础上执行的。二，我显然只想运行最后两个命令一次，但在CMAKE_Gambit_LINK_EXECUTABLE调用给定的命令之前。

有没有办法在创建对象之后但在它们链接之前执行自定义命令？

我查看了CMake/Modules中的其他一些编译器，但找不到真正能做到这一点的语言。而且这个条目似乎是添加新语言最完整的文档，官方文档似乎并没有真正提及它。

4

1 回答 1

2

以下技巧应该可以实现您的目标。该解决方案消除了这一点，gsc并且cmake并不总是相互配合，因为它们都有自己隐式处理文件扩展名的方式。无论如何，让我们开始吧。

我打算从内部复制的一系列命令cmake（文件名略有不同）是

gsc -c linkstub.scm
gsc -c factmodule.scm
gsc -c main.scm
gsc -obj linkstub.scm
gsc -obj factmodule.scm
gsc -obj main.scm
gsc -o linkstub.c -link factmodule.c main.c
gsc -obj linkstub.c
gsc -o test -exe factmodule.o main.o linkstub.o

这里，linkstub.scm是一个空的（生成的）虚拟文件。我们需要它来进行最终链接，因为我们无法修改<OBJECTS>传递给的列表CMAKE_Gambit_LINK_EXECUTABLE。对应的linkstub.c文件将是由gsc -o linkstub.c -link .... 这是通过add_custom_command及其PRE_LINK选项实现的（每次应该链接目标时执行命令）。相同的自定义命令也将其编译linkstub.c为目标文件；在linkstub.o最终链接开始之前，前一个被新创建的覆盖。通过这种方式，我们可以欺骗 CMake 吞下一个linkstub.o在所有其他对象文件已编译时更新的内容。

让我们开始吧。我们需要更改各自文件中的编译器命令和对象扩展名：

set(CMAKE_Gambit_COMPILE_OBJECT
    "<CMAKE_Gambit_COMPILER> -o <SOURCE>.c -c <SOURCE>"
    "<CMAKE_Gambit_COMPILER> -o <OBJECT> -obj <SOURCE>.c")

set(CMAKE_Gambit_OUTPUT_EXTENSION .o)

这有点脏，因为它会在您的源代码树中留下构建工件（也许您可以只在构建树之前添加一个路径 - 在这里，我们稍后会自动删除它们）。请注意，基于每个源进行编译也可以更好地扩展，因为您最初尝试中的链接步骤可能会变得非常大（所有.scm文件都被编译成可执行文件）。接下来，链接文件的占位符：.o.c

set(linkstub ${CMAKE_CURRENT_BINARY_DIR}/linkstub.scm)
file(WRITE ${linkstub} "")

同样，这只是将相应的对象文件获取到目标的对象依赖项中的一种手段。现在剩下的：

set(sources
    factmodule.scm
    main.scm)

list(TRANSFORM sources
    APPEND ".c"
    OUTPUT_VARIABLE cSources)

list(TRANSFORM cSources
    PREPEND "${CMAKE_CURRENT_SOURCE_DIR}/"
    OUTPUT_VARIABLE cSources)

list(REMOVE_ITEM cSources
    linkstub.scm.c)

add_executable(test ${sources} ${linkstub})

add_custom_command(TARGET test
    PRE_LINK
    COMMAND ${CMAKE_Gambit_COMPILER}
    -o
    ${CMAKE_CURRENT_BINARY_DIR}/linkstub.scm.c
    -link
    ${cSources}
    COMMAND ${CMAKE_Gambit_COMPILER}
    -o 
    ${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/test.dir/linkstub.scm.o
    -obj
    ${CMAKE_CURRENT_BINARY_DIR}/linkstub.scm.c
    COMMAND ${CMAKE_COMMAND} -E remove ${cSources})

最后一个命令完成了所有的魔法。它重新编写linkstub.scm.c，将其编译为目标文件，最后删除.scm.c源树中所有生成的文件。请注意，CMakeFiles/test.dir/其中一个路径中有一个丑陋的硬编码，应该有一种方法可以从目标查询此路径以解决此问题。

再次注意，文件扩展名在这里有些关键，解决方案很脆弱。CMake 似乎绝对需要.o附加的目标文件，即.scm.o. gsc但是，如果没有另行通知，将生成 a.c 而不是，.scm.c这会导致该-link步骤生成与编译成 . 的符号不匹配的符号.scm.o。

作为旁注，这种方法显然不处理方案源之间的任何动态/隐式依赖关系 - 如果您以需要重新转换和重新编译factmodule.scm的方式进行更改，这将不会为您解决。main.scm据我所知，目前没有办法教 CMake 你想注册一个解析.scm文件的自定义依赖扫描器。

似乎一个普通的老人makefile可能会做得更好。

于 2020-09-07T10:18:37.300 回答