5

是否可以通过代码确定当前系统是 R/3 还是 S/4？

我需要它，因为我有一个返回人力资源相关数据的软件组件的方法，但是这个组件应该不同于 R/3 和 S/4 系统。

    DATA(lv_software_component) = mo_configuration->get_software_component( ).

    SELECT * FROM tadir INTO TABLE @DATA(lt_inftype_tables)
            WHERE pgmid  = 'R3TR'
              AND object = 'TABL'
              AND devclass IN ( SELECT devclass FROM tdevc
                                               WHERE dlvunit = @lv_software_component
                                                  OR dlvunit = 'SAP_HRGXX'
                                                  OR dlvunit = 'SAP_HRRXX' )

例如，在 R/3 上lv_software_component应该是'SAP_HRCMX'，而在 S/4 上应该是'S4HCMCMX'。目前，我不知道如何以编程方式区分版本之间的区别。

我想出的最好的方法是硬编码SY-SYSID，因为我知道哪些系统是 S/4，哪些不是，但这不应该是理想的。

我很感激任何帮助，谢谢！

4

4 回答 4

8

您可以使用下面的类方法来确定它。另一方面 is_s4h 方法只存在于 S4 系统上。您需要在调用它之前检查方法退出。

cl_cos_utilities=>is_s4h( )

工作完整示例：

REPORT ZMKY_ISS4.
CLASS cl_oo_include_naming DEFINITION LOAD.

DATA oref TYPE REF TO if_oo_class_incl_naming.
DATA: lt_methods TYPE seop_methods_w_include,
      lv_clskey  TYPE seoclskey,
      ls_cpdkey  TYPE seocpdkey,
      lv_iss4    TYPE abap_bool,
      lt_params  TYPE abap_parmbind_tab.

lv_clskey = 'CL_COS_UTILITIES'.
oref ?= cl_oo_include_naming=>get_instance_by_cifkey( lv_clskey ).
lt_methods = oref->get_all_method_includes( ).
ls_cpdkey-clsname = lv_clskey.
ls_cpdkey-cpdname = 'IS_S4H'.
READ TABLE lt_methods WITH KEY cpdkey = ls_cpdkey TRANSPORTING NO FIELDS.
IF sy-subrc EQ 0.
  lt_params = VALUE #( ( name  = 'RV_IS_S4H'
                  kind  = cl_abap_objectdescr=>returning
                  value = REF #( lv_iss4 ) ) ).
  CALL METHOD CL_COS_UTILITIES=>('IS_S4H')
    PARAMETER-TABLE
      lt_params.
ELSE.
  lv_iss4 = abap_false.
ENDIF.
于 2020-08-25T19:13:13.737 回答
4

使用该方法cl_cos_utilities=>is_s4h是一个相当不干净的解决方案，因为旧版本中不存在该方法。

更简洁的方法是使用功能模块SFW_IS_BFUNC_SWITCHED_ON。该功能模块检查是否启用了交换机框架中的业务功能。

要检查 S4HANA 本地业务功能：

CALL FUNCTION 'SFW_IS_BFUNC_SWITCHED_ON'
  EXPORTING
    bfunc_name     = 'SIMPLIFY_ON_PREMISE'
  IMPORTING
    is_switched_on = is_s4.

要检查 S4HANA on Cloud 业务功能：

CALL FUNCTION 'SFW_IS_BFUNC_SWITCHED_ON'
  EXPORTING
    bfunc_name     = 'SIMPLIFY_PUBLIC_CLOUD'
  IMPORTING
    is_switched_on = is_s4.

顺便说一句：该方法cl_cos_utilities=>is_s4h实际上在内部使用了这个功能模块。

您可能还想检查在您的用例中是否更适合使用该功能模块来实际检测哪些 HR 业务功能处于活动状态，而不是从系统是否激活 S/4 中间接获取该信息。

于 2020-08-26T07:42:34.847 回答
2

OCS_GET_INSTALLED_COMPS有返回所有安装的软件组件的功能模块。请注意，它不是由 SAP 发布的。它曾经在旧系统中工作，现在仍然在 S/4HANA 中工作。

于 2020-08-25T20:01:10.763 回答
0

您可以使用功能模块DELIVERY_CHCK_ACTIVE_COMPONENT来检查两个组件中的哪个组件处于活动状态。

如果您确实需要检查它是 S/4 还是 R/3，我也很确定只有 S/4 系统才会激活 S4CORE 组件。

于 2020-08-25T19:39:34.477 回答