1

我正在使用以下命令将 GLSL 文件编译为 SPIR-V：

C:/VulkanSDK/1.2.148.1/Bin/glslc C:/Users/jonat/Projects/sum.comp -o C:/Users/jonat/Projects/sum.spv

得到错误：

error: 'subgroup op' : requires SPIR-V 1.3

错误发生在第 32 行和第 45 行，它们都是sum = subgroupAdd(sum);

完整的GLSL 代码：

#version 450
#extension GL_KHR_shader_subgroup_arithmetic : enable

layout(std430, binding = 0) buffer Input
{
   float inputs[];
};

layout(std430, binding = 1) buffer Output
{
   float outputs[];
};

layout (local_size_x_id = 1) in;
layout (constant_id = 2) const int sumSubGroupSize = 64;

layout(push_constant) uniform PushConsts
{
  int n;
} consts;

shared float sdata[sumSubGroupSize];

void main()
{
    float sum = 0.0;
    if (gl_GlobalInvocationID.x < consts.n)
    {
        sum = inputs[gl_GlobalInvocationID.x];
    }

    sum = subgroupAdd(sum);

    if (gl_SubgroupInvocationID == 0)
    {
        sdata[gl_SubgroupID] = sum;
    }

    memoryBarrierShared();
    barrier();

    if (gl_SubgroupID == 0)
    {
        sum = gl_SubgroupInvocationID < gl_NumSubgroups ? sdata[gl_SubgroupInvocationID] : 0;
        sum = subgroupAdd(sum);
    }

    if (gl_LocalInvocationID.x == 0)
    {
        outputs[gl_WorkGroupID.x] = sum;
    }
}

我有最新版本的 VulkanSDK。

4

1 回答 1

1

看起来您需要--target-env=vulkan1.1glslc 来发出 SPIR-V 1.3：

4.2.6。--target-env=

...

生成的代码使用 SPIR-V 1.0，但为 Vulkan 1.1 编译的代码使用 SPIR-V 1.3，以及为 Vulkan 1.5 编译的代码使用 SPIR-V 1.5。

如果未指定此选项，则使用默认值 vulkan1.0。

于 2020-08-20T03:26:55.563 回答