3

我看了另外两个似乎与此有关的问题，但它们有点迟钝，我无法将它们与我想做的事情联系起来，我认为这更简单。我也认为这将是一个非常常见的问题/任务的更清晰的陈述，所以我发布这个是为了像我这样的其他人的利益。

问题：

我有 3 个文件，每个文件都是一key=value对列表：

设置1.ini

key1=val1
key2=val2
key3=val3

设置2.ini

key1=val4
key2=val5
key3=val6

设置3.ini

key1=val7
key2=val8
key3=val9

毫不奇怪，我想将这些key=value对读入哈希以对它们进行操作，所以...

我有文件名的哈希：

my %files = { file1 => 'settings1.ini'
            , file2 => 'settings2.ini'
            , file3 => 'settings3.ini'
            };

我可以像这样遍历文件名：

foreach my $fkey (keys %files) {
    say $files{$fkey};
}

好的。

现在我想将key=value每个文件中的对列表添加到哈希中，作为每个“顶级”文件名键下的子哈希，这样我就可以像这样遍历它们：

foreach my $fkey (keys %files) {
    say "File: $files{$fkey}";
    foreach my $vkey (keys $files{$fkey}) {
        say "  $vkey: $files{$fkey}{$vkey}";
    }
}

换句话说，我想向散列添加第二级，以便它从只是（在伪术语中）单层值列表：

file1 => settings1.ini
file2 => settings2.ini
file3 => settings3.ini

成为一个多层值列表：

file1 => key1 => 'val1'
file1 => key2 => 'val2'
file1 => key3 => 'val3'

file2 => key1 => 'val4'
file2 => key2 => 'val5'
file2 => key3 => 'val6'

file3 => key1 => 'val7'
file3 => key2 => 'val8'
file3 => key3 => 'val9'

在哪里：

my $fkey = 'file2';
my $vkey  = 'key3';
say $files{$fkey}{$vkey};

将打印值

'val6'

作为旁注，我正在尝试成对File::Slurp阅读。key=value在单级哈希上执行此操作很好：

my %new_hash = read_file($files{$fkey}) =~ m/^(\w+)=([^\r\n\*,]*)$/img;

但是 - 重新表述这整个问题 - 我真正想做的是将新的哈希key=value对“嫁接”到现有的文件名哈希上“在”顶部$file键作为“子/分支”子哈希。

问题：

  • 我该怎么做，如何像这样一次构建一个多层哈希？
  • 我可以这样做而不必预先将哈希定义为多层吗？

我use strict;和所以我看到了

Can't use string ("string") as a HASH ref while "strict refs" in use at script.pl line <lineno>.

我不完全理解...

编辑：

感谢Timur Shtatland、Polar Bear和Dave Cross的精彩回答。在精神上分析您的建议时，我突然想到我在最初的问题中有些不一致，从而稍微误导了您。我道歉。我也想我现在明白为什么我看到了“严格的裁判”错误。我做了一些改变。

请注意，我第一次提到文件名的初始哈希是正确的。但是，随后循环的 foreach 示例%files是不正确的，因为我从file1用作第一个文件键变为settings1.ini用作第一个文件键。我认为这就是 Perl 抛出strict refs错误的原因——因为我试图将键从初始字符串更改为指向子哈希的 hash_ref（反之亦然）。

我理解正确吗？

4

3 回答 3

3

有几个用于 ini 文件的 CPAN 模块。你应该研究什么是可用的，然后选择你内心渴望的东西。

否则，您可以本着以下代码段的精神编写自己的代码

use strict;
use warnings;
use feature 'say';

use Data::Dumper;

my @files = qw(settings1.ini settings2.ini settings3.ini);

my %hash;

for my $file (@files) {
    $hash{$file} = read_settings($file);
}

say Dumper(\%hash);

sub read_settings {
    my $fname = shift;
    my %hash;
    
    open my $fh, '<', $fname
        or die "Couldn't open $fname";
    
    while( <$fh> ) {
        chomp;
        my($k,$v) = split '=';
        $hash{$k} = $v
    }
    
    close $fh;
    
    return \%hash;
}

输出

$VAR1 = {
          'settings1.ini' => {
                               'key2' => 'val2',
                               'key1' => 'val1',
                               'key3' => 'val3'
                             },
          'settings2.ini' => {
                               'key2' => 'val5',
                               'key1' => 'val4',
                               'key3' => 'val6'
                             },
          'settings3.ini' => {
                               'key1' => 'val7',
                               'key2' => 'val8',
                               'key3' => 'val9'
                             }
        };
于 2020-08-19T05:31:19.060 回答
2

要一次构建一层哈希，请使用匿名哈希。这里的每个值%files都是对哈希的引用，例如 for $files{'settings1.ini'}：

# read the data into %new_hash, then:
$files{'settings1.ini'} = { %new_hash }

您不需要预先将散列定义为多层（作为散列的散列）。

此外，避免重新发明轮子。将 Perl 模块用于常见任务，在这种情况下，请考虑使用Config::IniFiles 之类的东西来解析*.ini文件

也可以看看：

匿名哈希：perlreftut 哈希哈希
：perldsc

于 2020-08-19T03:50:35.953 回答
2

Perl 使这样的事情变得非常容易。

#!/usr/bin/perl

use strict;
use warnings;
use feature 'say';
use Data::Dumper;

my %files;

# <> reads from the files given on the command line
# one line at a time.
while (<>) {
  chomp;
  my ($key, $val) = split /=/;

  # $ARGV contains the name of the file that
  # is currently being read.
  $files{$ARGV}{$key} = $val;
}

say Dumper \%files;

运行如下：

$ perl readconf settings1.ini settings2.ini settings3.ini

给出以下输出：

$VAR1 = {
          'settings3.ini' => {
                               'key2' => 'val8',
                               'key1' => 'val7',
                               'key3' => 'val9'
                             },
          'settings2.ini' => {
                               'key3' => 'val6',
                               'key1' => 'val4',
                               'key2' => 'val5'
                             },
          'settings1.ini' => {
                               'key3' => 'val3',
                               'key1' => 'val1',
                               'key2' => 'val2'
                             }
        };
于 2020-08-19T08:55:32.017 回答