0

因此，本指南在这里展示了重叠内核执行和数据传输的一般方法。

cudaStream_t streams[nStreams];
for (int i = 0; i < nStreams; ++i) {
  cudaStreamCreate(&streams[i]);
  int offset = ...;
  cudaMemcpyAsync(&d_a[offset], &a[offset], streamBytes, cudaMemcpyHostToDevice, stream[i]);
  kernel<<<streamSize/blockSize, blockSize, 0, stream[i]>>>(d_a, offset);
  // edit: no deviceToHost copy
}

但是，内核是串行的。所以它必须处理 0->1000，然后 1000->2000，... 简而言之，在重叠数据传输时正确执行此内核的顺序是：

  • 复制[a->b] 必须在内核[a->b] 之前发生
  • kernel [a->b] 必须发生在 kernel[b->c] 之前，其中 c > a, b

不使用可以做到这一点cudaDeviceSynchronize()吗？如果没有，最快的方法是什么？

4

1 回答 1

4

所以每个内核都依赖于（直到不能开始）：

  1. 关联的 H->D 副本已完成
  2. 前面的内核执行完成

普通的流语义无法处理这种情况（2 个独立的依赖项，来自 2 个独立的流），因此我们需要在其中放置一个额外的互锁。我们可以使用一组事件并cudaStreamWaitEvent()对其进行处理。

对于最一般的情况（不知道块的总数）我会推荐这样的东西：

$ cat t1783.cu
#include <iostream>
#include <time.h>
#include <sys/time.h>
#define USECPSEC 1000000ULL

unsigned long long dtime_usec(unsigned long long start){

  timeval tv;
  gettimeofday(&tv, 0);
  return ((tv.tv_sec*USECPSEC)+tv.tv_usec)-start;
}

template <typename T>
__global__ void process(const T * __restrict__ in, const T * __restrict__ prev, T * __restrict__ out, size_t ds){

  for (size_t i = threadIdx.x+blockDim.x*blockIdx.x; i < ds; i += gridDim.x*blockDim.x){
    out[i] = in[i] + prev[i];
    }
}
const int nTPB = 256;
typedef int mt;
const int chunk_size = 1048576;
const int data_size = 10*1048576;
const int ns = 3;

int main(){

  mt *din, *dout, *hin, *hout;
  cudaStream_t str[ns];
  cudaEvent_t  evt[ns];
  for (int i = 0; i < ns; i++) {
    cudaStreamCreate(str+i);
    cudaEventCreate( evt+i);}
  cudaMalloc(&din, sizeof(mt)*data_size);
  cudaMalloc(&dout, sizeof(mt)*data_size);
  cudaHostAlloc(&hin,  sizeof(mt)*data_size, cudaHostAllocDefault);
  cudaHostAlloc(&hout, sizeof(mt)*data_size, cudaHostAllocDefault);
  cudaMemset(dout, 0, sizeof(mt)*chunk_size);  // for first loop iteration
  for (int i = 0; i < data_size; i++) hin[i] = 1;
  cudaEventRecord(evt[ns-1], str[ns-1]); // this event will immediately "complete"
  unsigned long long dt = dtime_usec(0);
  for (int i = 0; i < (data_size/chunk_size); i++){
    cudaStreamSynchronize(str[i%ns]); // so we can reuse event safely
    cudaMemcpyAsync(din+i*chunk_size, hin+i*chunk_size, sizeof(mt)*chunk_size, cudaMemcpyHostToDevice, str[i%ns]);
    cudaStreamWaitEvent(str[i%ns], evt[(i>0)?(i-1)%ns:ns-1], 0);
    process<<<(chunk_size+nTPB-1)/nTPB, nTPB, 0, str[i%ns]>>>(din+i*chunk_size, dout+((i>0)?(i-1)*chunk_size:0), dout+i*chunk_size, chunk_size);
    cudaEventRecord(evt[i%ns]);
    cudaMemcpyAsync(hout+i*chunk_size, dout+i*chunk_size, sizeof(mt)*chunk_size, cudaMemcpyDeviceToHost, str[i%ns]);
    }
  cudaDeviceSynchronize();
  dt = dtime_usec(dt);
  for (int i = 0; i < data_size; i++) if (hout[i] != (i/chunk_size)+1) {std::cout << "error at index: " << i << " was: " << hout[i] << " should be: " << (i/chunk_size)+1 << std::endl; return 0;}
  std::cout << "elapsed time: " << dt << " microseconds" << std::endl;
}
$ nvcc -o t1783 t1783.cu
$ ./t1783
elapsed time: 4366 microseconds

此处的良好做法是使用分析器来验证预期的重叠场景。但是，我们可以根据经过的时间测量走捷径。

该循环将总共 40MB 的数据传输到设备，然后再传回 40MB。经过的时间是4366us。这给出了 (40*1048576)/4366 或 9606 字节/us 的每个方向的平均吞吐量，即 9.6GB/s。这基本上使 Gen3 链路在两个方向上都饱和，因此我的块处理大约是背靠背的，并且我基本上完全重叠了 D->H 与 H->D 内存副本。这里的内核是微不足道的，因此它在配置文件中仅显示为条子。

对于您的情况，您表示不需要 D->H 副本，但它不会增加额外的复杂性，因此我选择展示它。如果您将该行注释到循环之外，仍会发生所需的行为（尽管这会影响稍后的结果检查）。

对这种方法的一个可能的批评是cudaStreamSynchronize()调用，这是必要的，因此我们不会“超越”事件联锁，这意味着循环将只进行ns迭代次数超出当前在设备上执行的迭代次数。因此，不可能异步启动更多的工作。如果您想立即启动所有工作并继续在 CPU 上执行其他操作，则此方法将不完全允许（当流处理ns从最后一个迭代达到迭代时，CPU 将继续通过循环）。

提供代码是为了从概念上说明一种方法。它不保证没有缺陷，我也不声称它适用于任何特定目的。

于 2020-08-15T04:25:06.927 回答