2

我使用以下函数对列表执行条件操作：

consider[data_, conditionCOL_, conditionVAL_, listOfCol_] :=
  Select[data, (#[[conditionCOL]] == conditionVAL) &][[All, listOfCol]]

考虑以下示例：

dalist = Join[Tuples[Range[4], 2]\[Transpose], {Range[16], Range[17, 32, 1]}
         ]\[Transpose];

在此处输入图像描述

我使用以下方法来获取函数定义的特定列的方法。这将输出第 3 列和第 4 列条目的平均值，其中第 1 列中的相应条目等于 2

Mean@consider[dalist, 1, 2, {3, 4}]

在此处输入图像描述

现在，我想在要平均的值上添加约束/阈值：

在以下情况下平均这些值：

  • 高于 minValue（例如，3）
  • 在 maxValue 下（例如，25）

下面给出一个示例，其平均值应在上述约束条件下计算。

在此处输入图像描述

4

2 回答 2

5

由于尚不清楚您是要从平均中排除超出限制的点，还是要决定是否执行平均，所以我将解决这两个问题。您可以使用以下函数对函数的结果进行后处理consider（根据您的数据格式，它们相当具体）：

filter[data : {{_, _} ..}, {min_, max_}] := 
   Select[data, min < #[[1]] < max && min < #[[2]] < max &]

dataWithinLimitsQ[data : {{_, _} ..}, {min_, max_}] := 
   data == filter[data, {min, max}]

meanFiltered[data : {{_, _} ..}, {min_, max_}] := 
   Mean@filter[data, {min, max}]

以下是如何使用它们：

In[365]:= dalist=Join[Tuples[Range[4],2]\[Transpose],{Range[16],Range[17,32,1]}]\[Transpose]
Out[365]= {{1,1,1,17},{1,2,2,18},{1,3,3,19},{1,4,4,20},{2,1,5,21},{2,2,6,22},{2,3,7,23},
{2,4,8,24},{3,1,9,25},{3,2,10,26},{3,3,11,27},{3,4,12,28},{4,1,13,29},{4,2,14,30},{4,3,15,31},
{4,4,16,32}}

In[378]:= considered = consider[dalist,1,1,{3,4}]

Out[378]= {{1,17},{2,18},{3,19},{4,20}}

In[379]:= filter[considered,{2,21}]

Out[379]= {{3,19},{4,20}}

In[380]:= dataWithinLimitsQ[considered,{2,21}]

Out[380]= False

In[381]:= meanFiltered[considered,{2,21}]

Out[381]= {7/2,39/2}
于 2011-06-08T16:03:47.697 回答
2

我会使用Cases：

inRange[data_, {min_, max_}] := Cases[data, {__?(min < # < max &)}, 1]

此表单还接受具有任意列数的数据。

dat = {{1, 2, 0}, {6, 7, 4}, {6, 7, 7}, {4, 5, 6}, {4, 5, 3}, {9, 7, 1}, {0, 3, 7}, {6, 2, 1}}

inRange[dat, {2, 7}]

(* Out = {{4, 5, 6}, {4, 5, 3}} *)
于 2011-06-09T13:25:36.053 回答