2

当在 AWS 控制台中创建 ASG（Auto Scaling Group）时，可以检查“从一个或多个负载均衡器接收流量”的选项？

我试图使用“aws_autoscaling_attachment”资源来做同样的事情，但是我在下面遇到错误。我可以看到控制台中存在“MyALBWP”。

错误：使用弹性负载均衡器附加 AutoScaling 组 MyWPReaderNodesASGroup 失败：arn:aws:elasticloadbalancing:eu-west-2:262702952852:loadbalancer/app/MyALBWP/ef1dd71d87b8742b：ValidationError：提供的负载均衡器可能无效。请确保它们存在并重试。

resource "aws_launch_configuration" "MyWPLC" {
  name          = "MyWPLCReaderNodes"
  #count                = 2     Was giving error as min, max size is mentioned in ASG
  #name_prefix          = "LC-"  Error: "name_prefix": conflicts with name
  image_id      =  aws_ami_from_instance.MyWPReaderNodes.id
  instance_type = "t2.micro"
  iam_instance_profile = aws_iam_instance_profile.MyWebInstanceProfile2.name # Attach S3 role to EC2 Instance
  security_groups    = [aws_security_group.WebDMZ.id]  # Attach WebDMZ SG
  user_data          = file("./AutoScaleLaunch.sh")
  lifecycle {
    #prevent_destroy       = "${var.prevent_destroy}"
    create_before_destroy = true
  }
  #   tags = {     NOT VALID GIVES ERROR
  #   Name = "MyWPLC"
  # }

}

# # Create AutoScaling Group for Reader Nodes
# Name: MyWPReaderNodesASGroup
# Launch Configuration : MyWPLC
# Group Size : 2
# Network : Select your VPC
# Subnets : Select your public Subnets
# Receive traffic from Load Balancer   <<< Tried in "aws_autoscaling_attachment" gives 
# Target Group : MyWPInstances
# Health Check : ELB or EC2, Select ELB
# Health check grace period : 60 seconds
# tags name MyWPReaderNodesGroup

resource "aws_autoscaling_group" "MyWPReaderNodesASGroup" {
  name                      = "MyWPReaderNodesASGroup"
  # We want this to explicitly depend on the launch config above
  depends_on = [aws_launch_configuration.MyWPLC]
  max_size                  = 2
  min_size                  = 2
  health_check_grace_period = 60
  health_check_type         = "ELB"
  desired_capacity          = 2
  force_delete              = true
  launch_configuration      = aws_launch_configuration.MyWPLC.id
  vpc_zone_identifier       = [aws_subnet.PublicSubNet1.id, aws_subnet.PublicSubNet2.id]
  target_group_arns = [aws_lb_target_group.MyWPInstancesTG.arn] #  A list of aws_alb_target_group ARNs, for use with Application or Network Load Balancing.
  #target_group_arns = [aws_lb.MyALBWP.id] #  A list of aws_alb_target_group ARNs, for use with Application or Network Load Balancing.
  #error: ValidationError: Provided Target Groups may not be valid. Please ensure they exist and try again.
  # tags = {        NOT REQUIRED GIVES ERROR  : Error : Inappropriate value for attribute "tags": set of map of string required.
  #   Name = "MyWPReaderNodesGroup"
  # }
}

# Create a new load balancer attachment
# ERROR: Failure attaching AutoScaling Group MyWPReaderNodesASGroup with Elastic Load Balancer: arn:aws:elasticloadbalancing:eu-west-2:262702952852:loadbalancer/app/MyALBWP/ef1dd71d87b8742b: 
# ValidationError: Provided Load Balancers may not be valid. Please ensure they exist and try again.

resource "aws_autoscaling_attachment" "asg_attachment_elb" {
  autoscaling_group_name = aws_autoscaling_group.MyWPReaderNodesASGroup.id
  elb                    = aws_lb.MyALBWP.id
}
4

2 回答 2

3

aws_autoscaling_attachment资源应使用参数alb_target_group_arn。您可以使用aws_lb_target_group.MyWPInstancesTG.arn用于创建自动缩放组的参数。

该elb参数适用于经典负载均衡器，而不是应用程序负载均衡器。

更多信息可在此处获得。

于 2020-06-24T15:43:08.297 回答
3

关于 AutoScaling 组和 ASG 附件的注意事项：Terraform 当前提供独立的 ASG 附件资源（描述附加到 ELB 的 ASG）和具有定义内联的AutoScaling 组资源。load_balancers目前，您不能将具有内联负载平衡器的 ASG 与 ASG 附件资源结合使用。这样做会导致冲突并覆盖附件。

来自资源：aws_autoscaling_attachment 文档。

你有两个选择：

  1. 删除aws_autoscaling_attachment资源
  2. 从 aws_autoscaling_group 资源中删除target_group_arns参数，从aws_autoscaling_attachment资源中删除 use elb参数，并将alb_target_group_arn添加到aws_autoscaling_attachment资源

选项 1 如下所示：

resource "aws_autoscaling_group" "MyWPReaderNodesASGroup" {
  name                      = "MyWPReaderNodesASGroup"
  # We want this to explicitly depend on the launch config above
  depends_on = [aws_launch_configuration.MyWPLC]
  max_size                  = 2
  min_size                  = 2
  health_check_grace_period = 60
  health_check_type         = "ELB"
  desired_capacity          = 2
  force_delete              = true
  launch_configuration      = aws_launch_configuration.MyWPLC.id
  vpc_zone_identifier       = [aws_subnet.PublicSubNet1.id, aws_subnet.PublicSubNet2.id]
  target_group_arns = [aws_lb_target_group.MyWPInstancesTG.arn] #  A list of aws_alb_target_group ARNs, for use with Application or Network Load Balancing.
}

选项 2 如下所示：

resource "aws_autoscaling_group" "MyWPReaderNodesASGroup" {
  name                      = "MyWPReaderNodesASGroup"
  # We want this to explicitly depend on the launch config above
  depends_on = [aws_launch_configuration.MyWPLC]
  max_size                  = 2
  min_size                  = 2
  health_check_grace_period = 60
  health_check_type         = "ELB"
  desired_capacity          = 2
  force_delete              = true
  launch_configuration      = aws_launch_configuration.MyWPLC.id
  vpc_zone_identifier       = [aws_subnet.PublicSubNet1.id, aws_subnet.PublicSubNet2.id]
}

resource "aws_autoscaling_attachment" "asg_attachment_elb" {
  autoscaling_group_name = aws_autoscaling_group.MyWPReaderNodesASGroup.id
  alb_target_group_arn = aws_lb_target_group.MyWPInstancesTG.arn
}
于 2020-06-24T23:22:43.900 回答