kdb - 将 KDB 表转换为特殊格式的字典

Question

我对 KDB/Q 很陌生，我的表格只有两列，如下所示：

id      value
100       a
101       b
100       c
102       d
103       e
100       f
102       g
101       e

我需要将此表转换为字典组的形式，就像这种格式一样

id  | x1   x2  x3  x4  x5  x6  x7  x8 
100 | a    ::  c   ::  ::   f  ::  ::
101 | ::   b  ::   ::  ::   :: ::  e
102 | ::  ::  ::   d   ::   ::  g  ::  
103 | ::  ::  ::   ::   e   f  ::  ::

我尝试使用 by 但它只给我 group by id 不能像键控表或字典那样转换

有人可以帮我做同样的事情吗？列名（x1、x2 等不重要）。

Answer 1

想想也许你正在寻找一个exec by from table

q)t:([]id:100 101 100 102 103 100 102 101;val:`a`b`c`d`e`f`g`e)
q)exec val by id from t
100| `a`c`f
101| `b`e
102| `d`g
103| ,`e
q)// if you need the (::)
q)exec {@[count[t]#(::);x;:;y]}[i;val] by id from t
100| `a :: `c :: :: `f :: ::
101| :: `b :: :: :: :: :: `e
102| :: :: :: `d :: :: `g ::
103| :: :: :: :: `e :: :: ::

Answer 2

听起来你想旋转：https ://code.kx.com/q/kb/pivoting-tables/

q)t:([]id:100 101 100 102 103 100 102 101;val:`a`b`c`d`e`f`g`e)
q)exec distinct[t`val]#val!val by id:id from t
id | a b c d e f g
---| -------------
100| a   c     f
101|   b     e
102|       d     g
103|         e