delphi - 如何使用TScrollbar进行丰富编辑；

Question

如何使用 Tscrollbar 到 Richedit。

我的目的是在不同的面板中分离滚动条。

是否可以？

Answer 1

我不确定我是否理解这个问题，但如果我做对了，你最好的选择可能是在滚动框中进行丰富的编辑并使用 Windows 消息来同步两者。

安德烈亚

Answer 2

你可以试试这个：

procedure TForm1.ScrollBar1Scroll(Sender: TObject; ScrollCode: TScrollCode; var ScrollPos: Integer);
var
  WParam: longint;

begin
  case ScrollCode of
    scLineUp: WParam := SB_LINEUP;
    scLineDown: WParam := SB_LINEDOWN;
    scPageUp: WParam := SB_PAGEUP;
    scPageDown: WParam := SB_PAGEDOWN;
    scEndScroll: WParam := SB_ENDSCROLL;
    scPosition: WParam := SB_THUMBPOSITION;
    scTrack: WParam := SB_THUMBTRACK;
    else
      exit;
  end;
  WParam := WParam or word(ScrollPos) shl 16;

  RichEdit1.Perform(WM_VSCROLL, WParam, 0);
end;

procedure TForm1.RichEdit1Change(Sender: TObject);
var
  ScrollInfo: TScrollInfo;

begin
  FillChar(ScrollInfo, SizeOF(ScrollInfo), 0);
  ScrollInfo.cbSize := SizeOf(ScrollInfo);
  ScrollInfo.fMask := SIF_RANGE or SIF_PAGE or SIF_POS;
  if GetScrollInfo(RichEdit1.Handle, SB_VERT, ScrollInfo) then
  begin
    ScrollBar1.Max := ScrollInfo.nMax;
    ScrollBar1.Min := ScrollInfo.nMin;
    ScrollBar1.PageSize := ScrollInfo.nPage;
    ScrollBar1.Position := ScrollInfo.nPos;
  end;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  RichEdit1Change(self);
end;

它将 Scrollbar1: TScrollBar 与 RichEdit 的滚动信息同步，并模拟来自滚动条的 WM_VSCROLL 消息。但是，它要求 RichEdit 有自己的垂直滚动条可见，因为如果滚动信息不可见，则不会更新它。

AFAIK 没有其他方法可以获取滚动数据，这仅仅是因为 RichEdit 控件在不需要时不会创建它们（ScrollBars 属性中的 ssNone）。