2

我想禁用名称存储在数据库中的 UI 元素（控件、组件等）。
我的代码适用于控件，但我想访问（禁用它们）ToolStripItems，例如 ToolStripButtons、ToolStripMenuItems 等。

这是我当前的代码： 

Dim df_command As New SqlCommand("select * from treftab where ref_data = 'INTERVENTION' and ref_code  = '0'", sfacon)
Dim df_reader As SqlDataReader = df_command.ExecuteReader

If df_reader.HasRows Then
    While df_reader.Read
        Dim reftext As String = df_reader("ref_text")
        Dim someVariable As Control = Nothing
        Dim SearchedControls = Me.Controls.Find(key:=reftext, searchAllChildren:=True)
        someVariable = SearchedControls(0)
        someVariable.Enabled = False
    End While
End If
4

2 回答 2

2

在 Form.Control 集合中找不到 ToolStrip 或 MenuStrip 项，因为这些 UI 元素不是控件，而是一种特殊的组件。
虽然 ToolStrip 和 MenuStrip 都继承自 Control，但 ToolStripMenuItems 继承自 Component 和ToolStripItem（后者提供Enabled属性）。

Dictionary(Of String, Boolean)您可以根据存储在您拥有的数据源中的值 构建一个包含要启用或禁用的 UI 元素的名称。

使用读取当前表单的字段的方法，KeyValuePairs在字典中循环查找匹配字典的元素，并根据对应Keys的属性设置属性。 EnableValues

例如，禁用集合中的所有元素：（
我假设您在数据源中为每个表单存储了所有不同的名称） 

Dim names As New Dictionary(Of String, Boolean)()    

' [...]
While df_reader.Read()
    names.Add(df_reader("ref_text").ToString(), False)
End While

EnableDisableFormElements(Me, names)

该方法使用Type.GetFields()查找指定Form 的所有非公共实例字段，FieldInfo.GetValue()获取该字段表示的UI 元素的实例。

然后，它确定 UI 元素是 Control 还是 ToolStripItem（从这些基类继承的 UI 元素具有Enabled属性）并使用存储在 Dictionary 中的 Value 对其进行设置。

TrimStart("_"c)是因为 VB.Net 有（IMO）坏习惯，在这些字段名称中添加下划线。使用 C# 不会发生这种情况。 

Imports System.Reflection
Imports System.Windows.Forms

Private Sub EnableDisableFormElements(parentForm As Form, elementNames As Dictionary(Of String, Boolean))
    Dim allFields = parentForm.GetType().GetFields(BindingFlags.NonPublic Or BindingFlags.Instance)

    For Each element As KeyValuePair(Of String, Boolean) In elementNames
        Dim searchElement = allFields.FirstOrDefault(
        Function(f) f.Name.TrimStart("_"c).Equals(element.Key)).GetValue(parentForm)

        If searchElement IsNot Nothing Then
            If TypeOf searchElement Is Control Then
                DirectCast(searchElement, Control).Enabled = element.Value
            ElseIf TypeOf searchElement Is ToolStripItem Then
                DirectCast(searchElement, ToolStripItem).Enabled = element.Value
            End If
        End If
    Next
End Sub
于 2020-05-29T04:07:22.637 回答
1

ToolStrip和派生控件MenuStrip、ContextMenuStrip、StatusStrip的项目集合是ToolStripItemCollection ，它具有用于深度搜索的Find方法，就像ControlCollection.Find方法一样。因此，您必须通过上述控件的Items属性搜索此集合，以查找ToolStripItem或任何派生类型。

为上述类创建搜索功能：

Public Function GetToolStripItem(toolStrip As ToolStrip, key As String) As ToolStripItem
    Return toolStrip.Items.Find(key, True).FirstOrDefault
End Function

...并按如下方式调用它：

'Search a MenuStrip
Dim tsi = GetToolStripItem(MenuStrip1, key)

'Search a ToolStrip
Dim tsi = GetToolStripItem(ToolStrip1, key)

'Search a ContextMenuStrip
Dim tsi = GetToolStripItem(ContextMenuStrip1, key)

'Search a StatusStrip
Dim tsi = GetToolStripItem(StatusStrip1, key)

If tsi IsNot Nothing Then
    tsi.Enabled = False
End If

此外，您可以使用TypeOf运算符来确定项目的类型：

If TypeOf tsi Is ToolStripMenuItem Then
    '...
End If

If TypeOf tsi Is ToolStripDropDownItem Then
    '...
End If

If TypeOf tsi Is ToolStripButton Then
    '...
End If

...并使用迭代器函数从集合中获取所有或特定类型的项目：

Public Iterator Function GetAllToolStripItems(items As ToolStripItemCollection) As _
    IEnumerable(Of ToolStripItem)
    For Each tsi As ToolStripItem In items
        Yield tsi

        If TypeOf tsi Is ToolStripDropDownItem Then
            For Each ddi As ToolStripItem In
            GetAllToolStripItems(DirectCast(tsi, ToolStripDropDownItem).DropDownItems)
                Yield ddi
            Next
        End If
    Next
End Function

Public Iterator Function GetAllToolStripItems(Of T)(items As ToolStripItemCollection) As _
    IEnumerable(Of T)
    For Each tsi In items
        If TypeOf tsi Is T Then
            Yield DirectCast(tsi, T)
        ElseIf TypeOf tsi Is ToolStripDropDownItem Then
            For Each ddi In
            GetAllToolStripItems(Of T)(DirectCast(tsi, ToolStripDropDownItem).DropDownItems)
                Yield ddi
            Next
        End If
    Next
End Function

...以及用法：

'Get them all...
Dim items = GetAllToolStripItems(TooStrip1.Items) 'or any derived control...

'Get for example the ToolStripComboBox items...
Dim items = GetAllToolStripItems(Of ToolStripComboBox)(MenuStrip1.Items)

请注意，在迭代器中，识别ToolStripDropDownItem是获取派生类的 ToolStripItemCollection 所必需的，包括：

每个都继承DropDownItems属性，当然应该将其传递给迭代器。

于 2020-05-29T04:44:41.667 回答