1

我想使用 wxPerl 在带有平铺位图的框架上设置背景。在wxWidgets的示例的帮助下，我提出了以下代码。不幸的是，它什么也没做，框架保持空白。这甚至是正确的方法，还是有另一种方法？

use warnings;
use strict;

package MyFrame;
use Wx qw(:everything);
use base qw( Wx::Frame );

sub new {
    my ( $class, $path ) = @_;
    my $self
        = $class->SUPER::new( undef, -1, 'Test', [ -1, -1 ], [ 600, 400 ], );
    $self->set_tiling_background($path);
    return $self;
}

sub set_tiling_background {
    my ( $self, $path ) = @_;

    ## Create a wxBitmap from the file
    my $file = IO::File->new($path);
    binmode $file;

    my $handler = Wx::BMPHandler->new();
    my $image   = Wx::Image->new();
    $handler->LoadFile( $image, $file );
    my $bitmap = Wx::Bitmap->new($image);

    ## Just to check that the bitmap is good.
    $bitmap->SaveFile('saved.bmp', wxBITMAP_TYPE_BMP);

    ## Draw the bitmap tiling over the frame
    ## https://github.com/wxWidgets/wxWidgets/blob/master/src/html/htmlwin.cpp
    my $dc = Wx::WindowDC->new($self);

    my $size_x = $bitmap->GetWidth;
    my $size_y = $bitmap->GetHeight;

    for ( my $x = 0; $x < 600; $x += $size_x ) {
        for ( my $y = 0; $y < 400; $y += $size_y ) {
            $dc->DrawBitmap( $bitmap, $x, $y, 0 );
        }
    }
}

package MyApp;
use base 'Wx::App';
my $path = '/path/to/bitmap.bmp';

sub OnInit {
    my ($self) = @_;
    my $frame = MyFrame->new($path);
    $frame->Show(1);
}

package main;
MyApp->new->MainLoop;
4

2 回答 2

2

接受的答案已经解释了如何正确地做到这一点，但我也想解释一下你最初做错了什么：你不能WindowDC只画一次就希望完成任何事情。任何持久绘图都必须PaintDC在EVT_PAINT处理程序中完成，或者作为一种特殊的例外，在提供给EVT_BACKGROUND_ERASE处理程序的 DC 上完成。如果您设置EVT_PAINT处理程序调用您的原始文件set_tiling_background并PaintDC从中使用它，它也会起作用。

事实上，在现代平台（GTK3、macOS）上，您既不能使用也不能使用WindowDC，ClientDC在它们上绘图根本行不通。

于 2020-05-28T10:44:13.157 回答
2

这是使用ERASE_BACKGROUND事件处理程序的示例：

package MyFrame;
use Wx qw(:everything wxBITMAP_TYPE_JPEG);
use base qw( Wx::Frame );
use feature qw(say);
use strict;
use warnings;
use Wx::Event;

sub new {
    my ( $class, $path ) = @_;
    my $self
        = $class->SUPER::new( undef, -1, 'Test', [ -1, -1 ], [ 600, 400 ], );
    my $bitmap = Wx::Bitmap->new( $path , wxBITMAP_TYPE_JPEG );
    Wx::Event::EVT_ERASE_BACKGROUND( $self, sub { $self->setBgImage( $bitmap, @_) });
    return $self;
}

sub setBgImage {
    my ( $self, $bitmap, $frame, $evt ) = @_;

    return if !defined $evt;
    my $dc = $evt->GetDC();
    my $size_x = $bitmap->GetWidth;
    my $size_y = $bitmap->GetHeight;

    for ( my $x = 0; $x < 600; $x += $size_x ) {
        for ( my $y = 0; $y < 400; $y += $size_y ) {
            $dc->DrawBitmap( $bitmap, $x, $y, 0 );
        }
    }
}

package MyApp;
use base 'Wx::App';
my $path = 'logo.jpg';

sub OnInit {
    my ($self) = @_;
    my $frame = MyFrame->new($path);
    $frame->Show(1);
}

package main;
MyApp->new->MainLoop;

这给了我在 Ubuntu 20.04 上的以下输出：

在此处输入图像描述

另请参阅：wxPython：将背景图像放在面板上

于 2020-05-28T09:35:11.640 回答