2

我终于设法使用 VESA BIOS Extensions (1920px * 1080px, 24bpp) 在屏幕上绘制了一个青色像素。

;esi = bytes per scan line
;edx = physical address of linear framebuffer memory.
;ebx = x coord * 3
;ecx = y coord

DrawPixel:
    push edx
    mov edx, 0
    mov eax, 0
    lea eax, [esi]
    ;mov ecx, 0
    mul ecx
    add eax, ebx
    jmp draw

draw:
    pop edx
    add edx, eax
    mov ebx, 0x3296fa

    mov [edx], ebx
    ret

我尝试以这种方式使用“for循环”在屏幕上绘制一条青色水平线：

mov edi, 1920
call drawLoop
jmp $

drawLoop:
    dec edi                                       ;decrease edi
    cmp edi, 0                                    ;is edi equal to zero?
    jl doneLoop                                   ;then return
    imul ebx, edi, 3                              ;multiply edi by three and save the result in ebx
    mov ecx, 0                                    ;y = 0
    mov esi, ModeInfoBlock + 10h
    mov edx, dword[ModeInfoBlock + 28h]
    call DrawPixel                                ;Draw it!
    jmp drawLoop                                  ;run this again

doneLoop:
    ret

但是，这不起作用：它会画一条绿线。

当我尝试使用绘图/绘图像素代码再次绘制垂直线时，它也不起作用。它在各处绘制具有随机颜色的像素。以下是我使用该DrawPixel函数绘制垂直线的方法：

%include "../kernel/Services/Display/display.asm"

kernel:
    mov edi, 1080
    call drawLoop
    jmp $

drawLoop:
    dec edi
    cmp edi, 0
    jl doneLoop
    mov ecx, edi
    mov ebx, 0
    mov esi, ModeInfoBlock + 10h
    mov edx, dword[ModeInfoBlock + 28h]
    call DrawPixel
    jmp drawLoop

doneLoop:
    ret

有什么办法可以解决这些问题？

4

2 回答 2

2

绘制水平线

根据评论，我通过仅向视频显示器写入 3 个字节而不是每个像素的 4 个字节来解决绘制水平线的问题。额外的字节改变了屏幕上下一个像素的颜色。我修改后的代码如下所示： 

DrawPixel:
    push edx
    mov edx, 0
    mov eax, 0
    mov eax, esi
    mul ecx
    add eax, ebx
    jmp draw

draw:
    pop edx
    add edx, eax
    mov word[edx], 0x96fa
    mov byte[edx + 2], 0x32
    ret

绘制垂直线

在生成垂直线的代码中，我设法通过替换mov esi, ModeInfoBlock + 10h为movzx esi, word[ModeInfoBlock + 10h].

因为该movzx指令将 16 位bytesPerScanLine值移动到 32 位esi寄存器中，其余部分用零填充。它代表“ mov e z ero e xtend ”。

我修改后的垂直绘图代码：

%include "../kernel/Services/Display/display.asm"
kernel:
    mov edi, 1920
    call drawLoop
    jmp $

drawLoop:
    dec edi
    cmp edi, 0
    jl doneLoop
    imul ebx, edi, 3
    mov ecx, edi
    movzx esi, word[ModeInfoBlock + 10h]
    mov edx, dword[ModeInfoBlock + 28h]
    call DrawPixel
    jmp drawLoop

doneLoop:
    ret

这些是我的最终绘图功能：

;esi = bytes per scan line
;edx = physical address of linear framebuffer memory.
;ebx = x coord * 3
;ecx = y coord

DrawPixel:
    push edx
    mov edx, 0
    mov eax, 0
    mov eax, esi
    mul ecx
    add eax, ebx
    jmp draw

draw:
    pop edx
    add edx, eax
    mov word[edx], 0x96fa
    mov byte[edx + 2], 0x32
    ret
于 2020-05-29T13:27:52.283 回答
2

让我们从重写DrawPixel例程开始。目前有点乱！

mul使用会不必要地破坏EDX寄存器的指令是没有意义的。最好使用imul.

而不是mov eax, 0 lea eax, [si]用来加载EAX寄存器，你为什么不简单地写mov eax, esi呢？

还有一个错误需要考虑。因为您正在使用 24 位真彩色屏幕，所以写入整个 dword（32 位）将更改相邻像素的一部分。

;esi = bytes per scan line
;edx = physical address of linear framebuffer memory.
;ebx = x coord * 3
;ecx = y coord

; IN (ebx,ecx,edx,esi) OUT () MOD (eax)
DrawPixel:
    mov     eax, esi                ; BytesPerScanLine
    imul    eax, ecx                ; BytesPerScanLine * Y
    add     eax, ebx                ; BytesPerScanLine * Y + X * 3
    mov     word [edx+eax], 0x96FA  ; Low word of RGB triplet
    mov     byte [edx+eax+2], 0x32  ; High byte of RGB triplet
    ret

这个新例程现在只修改EAX寄存器

主要部分有其自身的问题：

mov esi, ModeInfoBlock + 10h不会检索BytesPerScanLine信息。为此，您需要movzx esi, word [ModeInfoBlock + 10h]

循环在每次迭代中使用 2 个分支。完全可以用单个分支编写循环。

接下来是我的版本。因为新的DrawPixel例程保留了所有寄存器（除了EAX），所以可以进行很大的简化：

    xor     ebx, ebx                         ; X = 0  -> EBX = X * 3
    xor     ecx, ecx                         ; Y = 0
    movzx   esi, word [ModeInfoBlock + 10h]  ; BytesPerScanLine
    mov     edx, [ModeInfoBlock + 28h]       ; PhysBasePtr
    call    drawLoop
    jmp     $

drawLoop:
    call    DrawPixel                        ; Modifies EAX
    add     ebx, 3                           ; Like X = X + 1
    cmp     ebx, 1920*3                      ; Length of the line is 1920 pixels
    jb      drawLoop
    ret

我的版本从左到右绘制这条水平线。我相信它可能比从右到左绘制要快一点。

我没有使用单独的循环计数器 ( EDI)，而是通过三倍 X 坐标控制循环。除了其他好处（比如速度，因为cmp和jb配对很好），这减轻了寄存器使用的压力。

更好的水平和垂直线条绘制例程

尤其是绘制水平线和垂直线，重复调用DrawPixel例程不是一个好主意。一遍又一遍地计算像素的地址是浪费时间。下面我展示了一些专门用于这些任务的例程。

我添加了一些额外的更改：

  • 您不应该用寻址视频内存的技术细节来负担主程序。让图形例程检索BytesPerScanLine和PhysBasePtr值。
  • 主程序应处理 (X,Y) 级别的像素。那个“次3 ”的东西又是属于图形例程的技术细节。
  • 在绘图例程中对颜色进行硬编码非常不灵活。
; IN (eax,ebx,ecx,edx) OUT () MOD (eax)
; EAX = X
; EBX = Y
; ECX = Color
; EDX = Line length
HLine:
    push    edx
    push    edi
    movzx   edi, word [ModeInfoBlock + 10h]  ; BytesPerScanLine
    imul    edi, ebx                         ; BytesPerScanLine * Y
    imul    eax, 3                           ; X * 3
    add     edi, eax                         ; BytesPerScanLine * Y + X * 3
    add     edi, [ModeInfoBlock + 28h]       ; ... + PhysBasePtr
    mov     eax, ecx                         ; Color 24 bits
    shr     eax, 8
    imul    edx, 3                           ; Line length * 3
    add     edx, edi                         ; Address of the end of line
.a: mov     [edi], cx                        ; Low word of RGB triplet
    mov     [edi+2], ah                      ; High byte of RGB triplet
    add     edi, 3                           ; Like (X + 1)
    cmp     edi, edx
    jb      .a
    pop     edi
    pop     edx
    ret

上面的HLine例程从左到右绘制一条水平线。 

; IN (eax,ebx,ecx,edx) OUT () MOD (eax)
; EAX = X
; EBX = Y
; ECX = Color
; EDX = Line length
VLine:
    push    edx
    push    esi
    push    edi
    movzx   esi, word [ModeInfoBlock + 10h]  ; BytesPerScanLine
    mov     edi, esi
    imul    edi, ebx                         ; BytesPerScanLine * Y
    imul    eax, 3                           ; X * 3
    add     edi, eax                         ; BytesPerScanLine * Y + X * 3
    add     edi, [ModeInfoBlock + 28h]       ; ... + PhysBasePtr
    mov     eax, ecx                         ; Color 24 bits
    shr     eax, 8
    imul    edx, esi                         ; Line length * BytesPerScanLine
    add     edx, edi                         ; Address of the end of line
.a: mov     [edi], cx                        ; Low word of RGB triplet
    mov     [edi+2], ah                      ; High byte of RGB triplet
    add     edi, esi                         ; Like (Y + 1)
    cmp     edi, edx
    jb      .a
    pop     edi
    pop     esi
    pop     edx
    ret

上面的VLine例程从上到下绘制一条垂直线。

这是您可以使用这些的方式：

Main:
    xor     eax, eax                         ; X = 0
    xor     ebx, ebx                         ; Y = 0
    mov     ecx, 0x003296FA                  ; Color cyan
    mov     edx, 1920                        ; Line length
    call    HLine                            ; -> (EAX)
    mov     edx, 1080
    call    VLine                            ; -> (EAX)
    jmp     $
于 2020-05-31T22:33:50.210 回答