0

我有 XML 文件 myConfig.xml。

<?xml version="1.0" encoding="UTF-8" standalone="no"?>
<test1.test.com id="valueTest1"/>
<test2.test.com id="valueTest1"/>
<test3.test.com id="valueTest1"/>
<installpath>C:\Temp\TESTxyz</installpath>
<userInput>
<entry key="myPassword" value="Qwerty123!"/>
<entry key="myLogin" value="John"/>
</userInput>

我需要在 CMD 中的批处理脚本中更改 .

@echo off
setlocal EnableDelayedExpansion
set newValueInstallpath="D:\Work"

(for /F "delims=" %%a in (myConfig.xml) do (
set "line=%%a"
set "newLine=!line:installpath>=!"
if "!newLine!" neq "!line!" (
    set "newLine=<installpath>%newValueInstallpath%</installpath>"
)
echo !newLine!
)) > NEW_myConfig.xml

输出 - NEW_myConfig.xml

<?xml version="1.0" encoding="UTF-8" standalone="no"?>
<test1.test.com id="valueTest1"/>
<test2.test.com id="valueTest1"/>
<test3.test.com id="valueTest1"/>
<installpath>D:\Work</installpath>
<userInput>
<entry key="myPassword" value="Qwerty123"/>
<entry key="myLogin" value="John"/>
</userInput>

installpath 中的更改值已正确更改但 myPassword 剪切字符“！”中的值。如何让它不削减我的标记“！”

4

2 回答 2

0

延迟扩展是执行之前发生的最后一件事，即使在for元变量扩展之后也是如此。当现在这样的for元变量包含带有感叹号的值时，这将被延迟扩展消耗。解决方案是切换延迟扩展，使其仅在需要时启用，否则禁用：

@echo off
setlocal EnableExtensions DisableDelayedExpansion
set "newValueInstallpath=D:\Work"

(for /F "usebackq delims=" %%a in ("myConfig.xml") do (
    set "line=%%a"
    setlocal EnableDelayedExpansion
    set "newLine=!line:installpath>=!"
    if "!newLine!" neq "!line!" (
        set "newLine=<installpath>!newValueInstallpath!</installpath>"
    )
    echo(!newLine!
    endlocal
)) > "NEW_myConfig.xml"

endlocal
于 2020-05-15T12:42:21.920 回答
0

!通过在设置值之前启用延迟扩展，您自己有效地削减了扩展字符。

要保留该!值，请在分配值之前禁用延迟扩展，此时您可以启用它而不会丢失!

一个简短的例子：

@Echo Off
    For %%A in ("Installpath>Example" "Installpath>of" "Installpath>Expansion Preservation!") Do Call :Assign "%%~A"
    Setlocal EnableDelayedExpansion
    For /L %%I in (1,1,%Count%) Do Echo(!Line[%%I]!
    Pause
Exit /B

:Assign
    SetLocal DisableDelayedExpansion
    Set "Line=%~1"
    Set "Line=%Line:Installpath>=%"
    Set /A Count+=1
    Endlocal & Set "Line[%Count%]=%Line%" & Set "Count=%Count%"
Exit /B
于 2020-05-15T12:38:40.997 回答