2

使用函数'GUI_DOWNLOAD'遇到了一个小问题。试图在我创建的 .txt 文件的顶部附加一个标题行。我的解决方案是：

 CALL FUNCTION 'GUI_DOWNLOAD'
   EXPORTING
     filename              = lv_file
     filetype              = 'ASC'
     write_field_separator = 'X'
   TABLES
     data_tab              = it_outh. "internal table just with the header line

 CALL FUNCTION 'GUI_DOWNLOAD'
   EXPORTING
     filename              = lv_file
     filetype              = 'ASC'
     append                = 'X'
     write_field_separator = 'X'
   TABLES
     data_tab              = it_output. "internal table with selected data

该代码有效。但是格式很糟糕，因为长度不同（标题行和数据）

我的文件格式

在 it_outh 中使用较短的描述是解决该问题的唯一方法吗？或者你们中有人对我有更好的想法吗？

祝你今天过得愉快。

问候，丹尼斯

4

1 回答 1

1

这是一个快速的解决方法，如何将带有标题的 itab 对齐输出转换为文本：

FIELD-SYMBOLS: <fs_table> TYPE STANDARD TABLE.

DATA: lref_struct TYPE REF TO cl_abap_structdescr,
      o_table     TYPE REF TO data.

lref_struct ?= cl_abap_structdescr=>describe_by_name( 'CRCO' ).
DATA(components) = lref_struct->get_components( ).
DATA(fields) = VALUE ddfields( FOR line IN lref_struct->get_ddic_field_list( ) ( line ) ).

" making all types as char by replacing with existing PRZ char field
MODIFY components FROM VALUE abap_componentdescr( type = components[ name = 'PRZ' ]-type ) TRANSPORTING type WHERE name <> ''.

lref_struct = cl_abap_structdescr=>create( components ).
DATA(o_ref_table) = cl_abap_tabledescr=>create( p_line_type = lref_struct p_table_kind = cl_abap_tabledescr=>tablekind_std ).

CHECK o_ref_table IS BOUND.

CREATE DATA o_table TYPE HANDLE o_ref_table.
ASSIGN o_table->* TO <fs_table>.
APPEND INITIAL LINE TO <fs_table>. " reserving line for headers

SELECT
  CAST( mandt      AS CHAR( 12 ) ) AS mandt,
  CAST( objty      AS CHAR( 2 ) ) AS objty,
  CAST( objid      AS CHAR( 8 ) ) AS objid,
  CAST( laset      AS CHAR( 6 ) ) AS laset,
  CAST( endda      AS CHAR( 8 ) ) AS endda,
  CAST( lanum      AS CHAR( 4 ) ) AS lanum,
  CAST( begda      AS CHAR( 8 ) ) AS begda,
  CAST( aedat_kost AS CHAR( 8 ) ) AS aedat_kost,
  CAST( aenam_kost AS CHAR( 12 ) ) AS aenam_kost,
  CAST( kokrs      AS CHAR( 10 ) ) AS kokrs,
  CAST( kostl      AS CHAR( 6 ) ) AS kostl,
  CAST( lstar      AS CHAR( 12 ) ) AS lstar,
  CAST( lstar_ref  AS CHAR( 12 ) ) AS lstar_ref,
  CAST( forml      AS CHAR( 12 ) ) AS forml,
  CAST( prz        AS CHAR( 12 ) ) AS prz,
  CAST( actxy      AS CHAR( 12 ) ) AS actxy,
  CAST( actxk      AS CHAR( 12 ) ) AS actxk,
  CAST( leinh      AS CHAR( 12 ) ) AS leinh,
  CAST( bde        AS CHAR( 12 ) ) AS bde,
  CAST( sakl       AS CHAR( 1 ) ) AS sakl
  UP TO 10 ROWS
  FROM crco
  APPENDING CORRESPONDING FIELDS OF TABLE @<fs_table>.

" writing headers
ASSIGN <fs_table>[ 1 ] TO FIELD-SYMBOL(<empty>).
LOOP AT fields ASSIGNING FIELD-SYMBOL(<field>).
  ASSIGN COMPONENT <field>-fieldname OF STRUCTURE <empty> TO FIELD-SYMBOL(<heading>).
  CHECK sy-subrc = 0.
  <heading> = <field>-scrtext_m.
ENDLOOP.

CALL FUNCTION 'GUI_DOWNLOAD'
  EXPORTING
    filename     = 'C:\tab.txt'
    filetype       = 'ASC'
    write_field_separator = 'X'
  TABLES
    data_tab     = <fs_table>.

虽然，它不是那么简单，但它绝对可以完成工作

在此处输入图像描述

上面代码片段中使用的技巧：动态创建目标内部表，使所有字段 char 与真实 DB 表不同，然后在表顶部添加虚拟行并将所有标题放在那里。

这种方法需要额外的初步工作（如所有 DB 字段的显式转换），但我认为没有其他方法可以生成格式化的 TXT 输出。

于 2020-05-10T15:29:29.840 回答