0

我刚刚创建了我的第一个批处理文件，将我的手机图片整理到文件夹中（在 Windows 上）。它奏效了，我只是想知道是否有更有效的编码方式，因为以目前的形式，我必须经历所有可能的年月组合。

if exist 2018*.* md 2018
if exist 2019*.* md 2019
if exist 2020*.* md 2020
move    2018*.* 2018
move    2019*.* 2019
move    2020*.* 2020
if exist 2018\????_03_*.* md 2018\March
if exist 2018\????_04_*.* md 2018\April
if exist 2018\????_05_*.* md 2018\May
move    2018\????_04_*.*    2018\April
move    2018\????_05_*.*    2018\May
move    2018\????_03_*.*    2018\March
if exist 2019\????_03_*.* md 2019\March
if exist 2019\????_04_*.* md 2019\April
if exist 2019\????_05_*.* md 2019\May
move    2019\????_04_*.*    2019\April
move    2019\????_05_*.*    2019\May
move    2019\????_03_*.*    2019\March
if exist 2020\????_03_*.* md 2020\March
if exist 2020\????_04_*.* md 2020\April
if exist 2020\????_05_*.* md 2020\May
move    2020\????_04_*.*    2020\April
move    2020\????_05_*.*    2020\May
move    2020\????_03_*.*    2020\March
4

1 回答 1

0 
@echo off

for /f "tokens=1,2,* delims=_" %%A in ('
    dir /b /a-d ????_??_*.* ^| findstr /b "20[0-9][0-9]_"
') do (
    for %%D in (
        "01 January"
        "02 February"
        "03 March"
        "04 April"
        "05 May"
        "06 June"
        "07 July"
        "08 August"
        "09 September"
        "10 October"
        "11 November"
        "12 December"
    ) do (
        for /f "tokens=1,2" %%E in ("%%~D") do (
            if "%%~B" == "%%~E" (
                if not exist "%%~A\%%~F\" md "%%~A\%%~F\"
                if exist "%%~A\%%~F\" move "%%~A_%%~B_%%~C" "%%~A\%%~F\" >nul
            )
        )
    )
)

如果检测到前四个字符作为 21 世纪年份的数字并带有以下下划线????_??_*.*，则允许使用该模式。findstr然后它从第二个令牌中的 2 位数字中获取月份。它检查目录是否year\month\存在，如果不存在则创建它。如果目录year\month\存在，则将文件复制到目录中。

for变量：

  • A年份数字
  • B月份数字
  • C文件名的其余部分
  • D月份数字和名称
  • E月份数字
  • F月份名称

查看for /?以获取了解for循环的帮助。

于 2020-05-06T12:45:17.493 回答