4

我有一个 ColdFusion 应用程序，用于在我们的开发服务器和生产服务器之间传输文件。实际发送文件的代码如下：

ftp = new Ftp();
ftp.setUsername(username);
ftp.setPassword(password);
ftp.setServer(server);
ftp.setTimeout(1800);
ftp.setConnection('dev');
ftp.open();
ftp.putFile(transferMode="binary",localFile=localpath,remoteFile=remotepath);
ftp.close(connection='dev');

使用上述代码发送文件时，我的上限为 100KB/s（通过接收服务器上的 FileZilla 监控）。如果我使用 Windows 命令行 FTP 工具发送完全相同的文件，我的速度将超过 1000KB/s。

我用上面的代码创建了一个全新的文件，它对传输速度没有影响，所以我知道它与原始应用程序中的周围代码无关。

那么，是什么导致了这些极低的速度呢？

编辑：所有测试都在将文件从我的生产服务器传输到我的开发服务器。我也尝试使用<cfftp>标签而不是 cfscript，我得到了相同的结果。

编辑#2：我最终使用cfexecute了，代码如下：

从我的 FTP 脚本：

public function sendFiles(required string localpath, required string remotepath) {
    this.writeFtpInstructions(localpath);
    exe = "C:\Windows\system32\ftp.exe";
    params = "-s:" & request.localapproot & "/" & "upload.txt";
    outputfile = request.localapproot & '/ftp.log';
    timeout = 120;
    Request.cliExec(exe,params,outputfile,timeout);
}

public function writeFtpInstructions(required string localpath) {
    instructions = request.localapproot & "/" & "upload.txt";
    crlf = chr(13) & chr(10);
    data = "";
    data &= "open " & this.server & crlf;
    data &= this.username & crlf;
    data &= this.password & crlf;
    data &= "cd " & request.remoteapproot & crlf;
    data &= "put " & localpath & crlf;
    data &= "quit";
    FileWrite(instructions, data);
}

该cliExec()函数（创建包装器所必需的，因为在 cfscript 中没有等效cfexecute项）：

<cffunction name="cliExec">
    <cfargument name="name">
    <cfargument name="arguments">
    <cfargument name="outputfile">
    <cfargument name="timeout">
    <cfexecute
        name="#name#"
        arguments="#arguments#"
        outputFile="#outputfile#"
        timeout="#timeout#" />
</cffunction>
4

2 回答 2

3

根据我在 CF9 上使用 cfftp 的经验，无法传输更大的文件。如果您查看 FTP 服务器端的活动传输，您会注意到传输以最高速度开始，但随着越来越多的数据传输速度不断下降。在传输了 100 MB 之后，减少开始变得非常剧烈，直到最终达到个位数爬行。最终，传输超时并失败。我试图处理一个 330 MB 的文件，发现无法使用 cfftp 进行传输。cfexecute 不是我使用标准 Windows ftp.exe 的选项，因为它似乎不支持 SFTP。

我最终通过coldfusion寻找了一个外部java类并选择了JSch（http://www.jcraft.com/jsch/）。具有讽刺意味的是，CF9 似乎为 CFFTP (jsch-0.1.41m.jar) 使用了此类的变体，但使用最新下载的版本 (jsch-0.1.45.jar) 的结果却大不相同。

这是我为概念验证而整理的代码：

<cfscript>
    stAppPrefs = {
        stISOFtp = {
             server = 'sftp.server.com',
             port = '22',
             username = 'youser',
             password = 'pa$$w0rd'
        }
    };

    /* Side-Load JSch Java Class (http://www.jcraft.com/jsch/) */
    try {
        // Load Class Using Mark Mandel's JavaLoader (http://www.compoundtheory.com/?action=javaloader.index)
        /* 
        Add Mark's LoaderClass To The ColdFusion Class Path Under CF Admin:
        Java and JVM : ColdFusion Class Path : C:\inetpub\wwwroot\javaloader\lib\classloader-20100119110136.jar
        Then Restart The Coldfusion Application Service
        */
        loader = CreateObject("component", "javaloader.JavaLoader").init([expandPath("jsch-0.1.45.jar")]);
        // Initiate Instance
        jsch = loader.create("com.jcraft.jsch.JSch").init();
    }
    catch(any excpt) {          
        WriteOutput("Error loading ""jsch-0.1.45.jar"" java class: " & excpt.Message & "<br>");
        abort;
    }

    /* SFTP Session & Channel */
    try {
        // Create SFTP Session
        session = jsch.getSession(stAppPrefs.stISOFtp.username, stAppPrefs.stISOFtp.server, stAppPrefs.stISOFtp.port);
        // Turn Off & Use Username/Password
        session.setConfig("StrictHostKeyChecking", "no");
        session.setPassword(stAppPrefs.stISOFtp.password);
        session.connect();
        // Create Channel To Transfer File(s) On
        channel = session.openChannel("sftp");
        channel.connect();
    }
    catch(any excpt) { 
        WriteOutput("Error connecting to FTP server: " & excpt.Message & "<br>");
        abort;
    } 

    // Returns Array Of Java Objects, One For Each Zip Compressed File Listed In Root DIR
    // WriteDump(channel.ls('*.zip'));      
    // Get First Zip File Listed For Transfer From SFTP To CF Server
    serverFile = channel.ls('*.zip')[1].getFilename();

    /* Debug */
    startTime = Now();
    WriteOutput("Transfer Started: " & TimeFormat(startTime, 'hh:mm:ss') & "<br>");
    /* // Debug */

    /* Transfer File From SFTP Server To CF Server */
    try {
        // Create File On Server To Write Byte Stream To
        transferFile = CreateObject("java", "java.io.File").init(expandPath(serverFile));
        channel.get(serverFile, CreateObject("java", "java.io.FileOutputStream").init(transferFile));
        // Close The File Output Stream
        transferFile = '';
    }
    catch(any excpt) { 
        WriteOutput("Error transfering file """ & expandPath(serverFile) & """: " & excpt.Message & "<br>");
        abort;
    }

    /* Debug */
    finishTime = Now();
    WriteOutput("Transfer Finished: " & TimeFormat(finishTime, 'hh:mm:ss') & "<br>");
    expiredTime = (finishTime - startTime);
    WriteOutput("Duration: " & TimeFormat(expiredTime, 'HH:MM:SS') & "<br>");
    WriteOutput("File Size: " & NumberFormat(Evaluate(GetFileInfo(ExpandPath(serverFile)).size / 1024), '_,___._') & " KB<br>");
    WriteOutput("Transfer Rate: " & NumberFormat(Evaluate(Evaluate(GetFileInfo(ExpandPath(serverFile)).size / 1024) / Evaluate(((TimeFormat(expiredTime, 'H') * 60 * 60) + (TimeFormat(expiredTime, 'M') * 60) + TimeFormat(expiredTime, 'S')))), '_,___._') & " KB/Sec <br>");
    /* // Debug */

    channel.disconnect();
    session.disconnect();
    </cfscript>

结果：

Transfer Started: 09:37:57
Transfer Finished: 09:42:01
Duration: 00:04:04
File Size: 331,770.8 KB
Transfer Rate: 1,359.7 KB/Sec

实现的传输速度与我使用 FileZilla FTP 客户端和手动下载所获得的速度相当。我发现这种方法对于 cfftp 的不足是一个可行的解决方案。

于 2012-01-10T03:07:20.763 回答
2

我一直在寻找，但我没有关于为什么它变慢的答案。但是，理论上，您应该能够通过 windows 命令行使用 cfexecute 来执行此操作。您甚至可以创建一个批处理文件并在一次调用中完成。

于 2011-05-27T17:36:08.640 回答