tcl - tcl8.6：什么是内置等效于 stdlib 中的“atexit()”或 bash 中的“trap "..." EXIT"？

Question

我正在寻找一个内置或标准包，它提供与 stdlib'satexit()和 bash'相似或等效的功能trap "..." EXIT。

它应该捕获由于任何结束执行的编程方式而终止，包括以下所有内容：

• 自然到达脚本执行结束
• 显式调用exit
• 未被抓住error

Answer 1

在大多数情况下，拦截此类终止所需要做的就是拦截exit命令。

rename exit real_exit
proc exit args {
    puts "EXITING"; flush stdout; # Flush because I'm paranoid...
    tailcall real_exit {*}$args
}

如果您显式调用它显然会起作用，但是如果您只是放下脚本的结尾，在交互式会话中发出文件结束信号，或者您的脚本稍后有错误并以错误终止，它也会被调用信息。这是因为 Tcl C API 调用Tcl_Exit()通过调用来工作exit，如果它不退出进程，则直接退出本身。

小心退出脚本顺便说一句；它们中的错误比正常情况更难调试。

---

它不起作用的情况？主要是在解释器本身无法执行命令的情况下（可能是因为它已从自身下方删除）或某些信号关闭了解释器（例如，由于各种原因，默认情况下不处理 SIGINT）。

Answer 2

atexit基于@Donal的回答或多或少的完整：

proc atexit { procbody } {
    if { [catch {set oldbody [info body exit]}] } {
        rename exit builtin_exit
        set oldbody { builtin_exit $returnCode }
    }
    proc exit { {returnCode 0} } [subst -nocommands {
        apply [list [list {returnCode 0}] [list $procbody]] \$returnCode
        tailcall apply [list [list {returnCode 0}] [list $oldbody]] \$returnCode
    }]
}

---

示例代码atexit-test.tcl：

#!/usr/bin/tclsh8.6

source atexit.tcl

atexit {
    puts "EXITING($returnCode)"; flush stdout; # Flush because I'm paranoid...
}

atexit {
    puts "done($returnCode)..."; flush stdout; # Flush because I'm paranoid...
}

atexit {
    puts "almost($returnCode)..."; flush stdout; # Flush because I'm paranoid...
}

{*}$argv

puts "fell through argv for implicit exit..."

...和终端会话：

$ ./atexit-test.tcl 
fell through argv for implicit exit...
almost(0)...
done(0)...
EXITING(0)
$ ./atexit-test.tcl exit
almost(0)...
done(0)...
EXITING(0)
$ ./atexit-test.tcl exit 5
almost(5)...
done(5)...
EXITING(5)
$ ./atexit-test.tcl error "unhandled exception"
unhandled exception
    while executing
"{*}$argv"
    (file "./atexit-test.tcl" line 17)
almost(1)...
done(1)...
EXITING(1)
$