haskell - 如何使用 hsc2hs 绑定常量、函数和数据结构？

Question

我需要一个如何使用 hsc2hs 的例子，我想当我写一个头文件时：

// foo.h
#define PI 3.14159

typedef struct {
    int i1;
    int i2;
} foo;

struct foo2 {
    int i1;
    int i2;
};

int fooFkt(foo f);

然后创建一个 hsc 文件，如：

import Foreign
import Foreign.C

#include "foo.h"

使用hsc2hs：

{-# INCLUDE "foo.h" #-}
{-# LINE 1 "test.hsc" #-}
import Foreign
{-# LINE 2 "test.hsc" #-}
import Foreign.C


{-# LINE 5 "test.hsc" #-}

我不明白，我认为 hsc2hs 会为我导入所有需要的东西，比如PI

谁能给我一个更好的例子？

Answer 1

在 RWH ch 17之后，您需要引入一些将 CPI值绑定到 Haskell 中的符号的东西。

例如：

{-# LANGUAGE ForeignFunctionInterface #-}
{-# LANGUAGE CPP                      #-}

import Foreign
import Foreign.C

-- helpers
import Control.Applicative
import Control.Monad

#include "foo.h"

-- binding a symbol

-- Note that hsc2hs can't marshal floating point CPP values, so this will be "3"
-- c_pi :: CInt
-- c_pi = #const PI

-- Instead, bind to a function that returns a CFloat
pi' :: Float
pi' = realToFrac c_pi

foreign import ccall unsafe "my_pi" c_pi :: CFloat

当我们在这里时，我们还可以将结构编组到 Haskell 和从 Haskell 传出：

-- Marshalling for the struct foo

data Foo = Foo { i1, i2 :: Int }
    deriving Show

-- Define how to marshal foo structs

instance Storable Foo where
    sizeOf    _ = #{size foo}

    alignment _ = alignment (undefined :: CInt)

    poke p foo  = do
        #{poke foo, i1} p $ i1 foo
        #{poke foo, i2} p $ i2 foo

    peek p = return Foo
              `ap` (#{peek foo, i1} p)
              `ap` (#{peek foo, i2} p)

并绑定到fooFkt函数：

-- Import the function too

foreign import ccall "foo.h fooFkt"
    c_fooFkt :: Ptr Foo -> IO CInt

-- Marshal data to and from C

fooFkt :: Foo -> IO Int
fooFkt f = fromIntegral <$> with f c_fooFkt

完毕。

Answer 2

如果您实际使用来自以下的一些定义，它会起作用foo.h：

import Foreign
import Foreign.C

#include "foo.h"

pi = #const PI

给

{-# INCLUDE "foo.h" #-}
{-# LINE 1 "test.hsc" #-}
import Foreign
{-# LINE 2 "test.hsc" #-}
import Foreign.C


{-# LINE 5 "test.hsc" #-}

pi = 3
{-# LINE 7 "test.hsc" #-}

这是网络包中的一个真实世界使用示例：https ://github.com/haskell/network/blob/master/Network/Socket/ByteString/MsgHdr.hsc