2

我正在尝试通过 Haskell 类型系统对 kdb/q“原子和列表”进行建模。

在 kdb/q 中，所有数据都是从原子构建的。原子是特定数据类型的不可约值。Int、boolean 和 char 是原子的示例。列表是从原子构建的有序集合。由于 q 是一种向量语言，大多数内置操作都是原子的，因此它会递归到参数结构中，直到它到达原子。

例如：

(1;2;3) 是整数 1、2、3 的简单列表

(1.0;2;(3;4;5)) 是 1.0(float)、2(int) 和简单 int 列表 (3;4;5) 的一般列表

neg 是一个对一个数字求反的函数。例如：

否定 1 产生 -1

负 -1.0 产生 1f

否定 (1.0;2;(3;4;5)) 产生 (-1f;-2;(-3;-4;-5))。

这就是启发我尝试在 Haskell 类型中建模这种行为的原因。数据类型应由原子类型和列表组成。

以下是我目前所拥有的简化版本。我还进一步尝试使其成为可折叠和可遍历的实例。

data Atom = I Int
          | C Char
          | D Double 
          deriving Show

data Q a = QAtom a 
         | QList [Q a]
         deriving Show

instance Functor Q where
    fmap f (QAtom a) = QAtom (f a)
    fmap f (QList qs) = QList $ fmap (fmap f) qs

instance Foldable Q where
    foldMap f (QAtom a) = f a
    foldMap f (QList qs) = mconcat $ fmap (foldMap f) qs

instance Traversable Q where
    sequenceA (QAtom fa) = fmap QAtom fa
    sequenceA (QList []) = pure $ QList []
    sequenceA (QList (qfa:qfas)) = concatL <$> (sequenceA qfa) <*> (sequenceA (QList qfas))
        where
            concatL (QAtom a) (QList qas) = QList ((QAtom a):qas)

这就是我所拥有的并且它可以编译，但我并不特别喜欢 concatL 函数，它没有根据类型涵盖所有模式。一旦我开始向 Q 添加一个新的值构造函数 QDict [(Q Atom, Q a)]，情况就会变得更糟。

我是否正确地对原始数据建模？我是否应该尝试使其可遍历？但是，如果我需要将数据类型与 Maybe 或 Either 一起使用来建模错误，我认为 Traversable 是必要的。

任何建议表示赞赏。

编辑：编辑 q 代码格式

4

1 回答 1

7

编译器知道如何Traversable为您的类型自动派生实例。如果你这样做:set -ddump-deriv -dsuppress-all -XDeriveTraversable -XStandaloneDeriving然后deriving instance Traversable Q，你可以看到“正确”的答案。如果你把这些知识应用到你的实例中，你会得到：

instance Traversable Q where
    sequenceA (QAtom fa) = fmap QAtom fa
    sequenceA (QList qfas) = fmap QList (traverse sequenceA qfas)

或者，如果您想避免traverse支持sequenceA：

instance Traversable Q where
    sequenceA (QAtom fa) = fmap QAtom fa
    sequenceA (QList qfas) = fmap QList (sequenceA (fmap sequenceA qfas))

关键是列表本身是Traversable，因此您可以调用sequenceA它们而无需将它们的一部分重新包装为您自己的类型。

旁注，在您的Foldable实例中，而不是链接mconcatand fmap，只需foldMap再次使用，因为列表Foldable也是：

instance Foldable Q where
    foldMap f (QAtom a) = f a
    foldMap f (QList qs) = foldMap (foldMap f) qs
于 2020-02-11T04:35:23.470 回答