sql-server - SQL Server 2005 - 用前导零格式化十进制数（包括有符号小数！）

Question

我需要格式化数字，如： -

1.99
21.34
1797.94
-300.36
-21.99
-2.31

转换为 0000.00 的格式掩码，使用 SQL-Server 2005 T-SQL。保留点后的有符号整数和小数。这将用于金融系统的文本文件导出。它要求它采用这种格式。

例如-

0001.99
0021.34
1794.94
-0300.36
-0021.99
-0002.31

以前，它是在 MS Access 中完成的，Format([Total],"0000.00")但 SQL-Server 没有此功能。

Answer 1

;WITH t(c) AS
(
SELECT 1.99 UNION ALL 
SELECT 21.34  UNION ALL 
SELECT 1797.94  UNION ALL 
SELECT -300.36  UNION ALL 
SELECT -21.99  UNION ALL 
SELECT -2.31 
)
SELECT  
     CASE WHEN SIGN(c) = 1 THEN '' 
          ELSE '-' 
     END + REPLACE(STR(ABS(c), 7, 2), ' ','0') 
FROM t

退货

0001.99
0021.34
1797.94
-0300.36
-0021.99
-0002.31

Answer 2

你可以做一个这样的函数：

CREATE FUNCTION [dbo].padzeros 
(
    @money MONEY,
    @length INT
)
RETURNS varchar(100)
-- =============================================
-- Author:      Dan Andrews
-- Create date: 05/12/11
-- Description: Pad 0's
--
-- =============================================
-- select dbo.padzeros(-2.31,7)
BEGIN

DECLARE @strmoney VARCHAR(100), 
        @result VARCHAR(100)

SET @strmoney = CAST(ABS(@money) AS VARCHAR(100))
SET @result = REPLICATE('0',@length-LEN(@strmoney)) + @strmoney
IF @money < 0 
    SET @result = '-' + RIGHT(@result, LEN(@result)-1)

RETURN @result

END

例子：

select dbo.padzeros(-2.31,7)