10

有了量化的约束，我可以Eq (A f)很好地推导出来吗？但是，当我尝试导出 Ord (A f) 时，它失败了。当约束类具有超类时，我不明白如何使用量化约束。如何派生Ord (A f)和其他具有超类的类？

> newtype A f = A (f Int)
> deriving instance (forall a. Eq a => Eq (f a)) => Eq (A f)
> deriving instance (forall a. Ord a => Ord (f a)) => Ord (A f)
<interactive>:3:1: error:
    • Could not deduce (Ord a)
        arising from the superclasses of an instance declaration
      from the context: forall a. Ord a => Ord (f a)
        bound by the instance declaration at <interactive>:3:1-61
      or from: Eq a bound by a quantified context at <interactive>:1:1
      Possible fix: add (Ord a) to the context of a quantified context
    • In the instance declaration for 'Ord (A f)'

PS。我还检查了ghc 提案 0109-quantified-constraints。使用 ghc 8.6.5

4

1 回答 1

8

问题在于它Eq是 的超类Ord，并且该约束(forall a. Ord a => Ord (f a))不包含声明实例Eq (A f)所需的超类约束。Ord (A f)

  • 我们有(forall a. Ord a => Ord (f a))

  • 我们需要Eq (A f), 即 ,(forall a. Eq a => Eq (f a))我们所拥有的并没有暗示这一点。

解决方案：添加(forall a. Eq a => Eq (f a))到Ord实例中。

（我实际上不明白 GHC 给出的错误信息与问题有何关系。）

{-# LANGUAGE QuantifiedConstraints, StandaloneDeriving, UndecidableInstances, FlexibleContexts #-}

newtype A f = A (f Int)
deriving instance (forall a. Eq a => Eq (f a)) => Eq (A f)
deriving instance (forall a. Eq a => Eq (f a), forall a. Ord a => Ord (f a)) => Ord (A f)

或者更整洁一点：

{-# LANGUAGE ConstraintKinds, RankNTypes, KindSignatures, QuantifiedConstraints, StandaloneDeriving, UndecidableInstances, FlexibleContexts #-}

import Data.Kind (Constraint)

type Eq1 f = (forall a. Eq a => Eq (f a) :: Constraint)
type Ord1 f = (forall a. Ord a => Ord (f a) :: Constraint)  -- I also wanted to put Eq1 in here but was getting some impredicativity errors...

-----

newtype A f = A (f Int)
deriving instance Eq1 f => Eq (A f)
deriving instance (Eq1 f, Ord1 f) => Ord (A f)
于 2020-01-14T23:34:49.937 回答