3

我希望能够在 F# 中编写一个计算表达式，如果它引发异常，它将能够重试操作。现在我的代码看起来像：

let x = retry (fun() -> GetResourceX())
let y = retry (fun() -> GetResourceY())
let z = retry (fun() -> DoThis(x, y))
etc. (this is obviously an astract representation of the actual code)

我需要能够重试每个函数一定次数，这是我在其他地方定义的。

我在想一个计算表达式可以在这里帮助我，但我不明白它如何帮助我删除将每个右侧显式包装到 Retryable<'T>

我可以看到计算表达式看起来像：

let! x = Retryable( fun() -> GetResourceX())
etc.

我知道 Monads 以粗略的方式是包装器类型，但我希望有办法解决这个问题。我知道我可以重载一个运算符，并且有一个非常简洁的语法来将一个操作转换为 Retryable<'T>，但对我来说，这只是让重复/包装更简洁；它还在那里。我可以将每个函数包装成一个 Retryable<'T>，但是再一次，我看不到做文章顶部所做的事情的价值（在每个操作上调用重试。至少它非常明确）。

也许计算表达式在这里是错误的抽象，我不确定。关于可以在这里做什么的任何想法？

4

3 回答 3

6

计算表达式有一些扩展（除了标准的 monadic 特性），这给你一个很好的方法来做到这一点。

正如您所说，单子本质上Retryable<'T>是具有一些附加行为的包装器（创建 eg ）。但是，F# 计算表达式也可以定义Run自动解包值的成员，因此 的结果retry { return 1 }可以只有一个 type int。

这是一个示例（构建器如下）：

let rnd = new System.Random()
// The right-hand side evaluates to 'int' and automatically
// retries the specified number of times
let n = retry { 
  let n = rnd.Next(10)
  printfn "got %d" n
  if n < 5 then failwith "!"  // Throw exception in some cases
  else return n }

// Your original examples would look like this:
let x = retry { return GetResourceX() }
let y = retry { return GetResourceY() }
let z = retry { return DoThis(x, y) }

这是retry构建器的定义。它不是真正的 monad，因为它没有定义let!（当您使用retry在另一个retry块中创建的计算时，它只会根据需要重试内部的 X 次和外部的 Y 次）。

type RetryBuilder(max) = 
  member x.Return(a) = a               // Enable 'return'
  member x.Delay(f) = f                // Gets wrapped body and returns it (as it is)
                                       // so that the body is passed to 'Run'
  member x.Zero() = failwith "Zero"    // Support if .. then 
  member x.Run(f) =                    // Gets function created by 'Delay'
    let rec loop(n) = 
      if n = 0 then failwith "Failed"  // Number of retries exceeded
      else try f() with _ -> loop(n-1)
    loop max

let retry = RetryBuilder(4)
于 2011-05-09T20:30:00.333 回答
3

一个简单的功能可以工作。

let rec retry times fn = 
    if times > 1 then
        try
            fn()
        with 
        | _ -> retry (times - 1) fn
    else
        fn()

测试代码。

let rnd = System.Random()

let GetResourceX() =
    if rnd.Next 40 > 1 then
        "x greater than 1"
    else
        failwith "x never greater than 1" 

let GetResourceY() =
    if rnd.Next 40 > 1 then
        "y greater than 1"
    else
        failwith "y never greater than 1" 

let DoThis(x, y) =
    if rnd.Next 40 > 1 then
        x + y
    else
        failwith "DoThis fails" 


let x = retry 3 (fun() -> GetResourceX())
let y = retry 4 (fun() -> GetResourceY())
let z = retry 1 (fun() -> DoThis(x, y))
于 2011-05-09T20:32:28.627 回答
0

这是在单个计算表达式中执行此操作的第一次尝试。但请注意，这只是第一次尝试；我还没有彻底测试过。此外，在计算表达式中重新设置尝试次数时有点难看。我认为可以在这个基本框架内对语法进行很好的清理。

let rand = System.Random()

let tryIt tag =
  printfn "Trying: %s" tag
  match rand.Next(2)>rand.Next(2) with
  | true -> failwith tag
  | _ -> printfn "Success: %s" tag

type Tries = Tries of int

type Retry (tries) =

  let rec tryLoop n f =
    match n<=0 with
    | true -> 
      printfn "Epic fail."
      false
    | _ -> 
      try f()
      with | _ -> tryLoop (n-1) f 

  member this.Bind (_:unit,f) = tryLoop tries f 
  member this.Bind (Tries(t):Tries,f) = tryLoop t f
  member this.Return (_) = true

let result = Retry(1) {
  do! Tries 8
  do! tryIt "A"
  do! Tries 5
  do! tryIt "B"
  do! tryIt "C" // Implied: do! Tries 1
  do! Tries 2
  do! tryIt "D" 
  do! Tries 2
  do! tryIt "E"
}


printfn "Your breakpoint here."

ps 但我更喜欢 Tomas 和 gradbot 的版本。我只是想看看这种类型的解决方案可能是什么样子。

于 2011-05-12T14:38:07.540 回答