flash - AS3 - 当类具有参数化构造函数时克隆类对象

Question

我想克隆一个类对象。我尝试从这里开始：

package
{
    import flash.net.registerClassAlias;
    import flash.utils.ByteArray;

    public class MyClass
    {
        public var property1:String;
        public var property2:Array;

        public function clone():MyClass
        {
            registerClassAlias("MyClass", MyClass);

            var bytes:ByteArray = new ByteArray();
            bytes.writeObject(this);
            bytes.position = 0;

            return bytes.readObject() as MyClass;
        }
    }
}

但这只适用于类具有默认构造函数而不是参数化构造函数时：

当类具有参数化构造函数时如何克隆类对象的任何想法？

问候

Answer 1

这是我能为你做的最好的：

package
{

    import flash.display.Sprite;


    public class Thing extends Sprite
    {

        // Cloneable properties.
        private var _cloneable:Array = ["x","y","val1","val2"];


        // Properties.
        public var val1:uint = 10;
        public var val2:String = "ten";


        /**
         * Returns a new Thing with the same properties.
         */
        public function clone():Thing
        {
            var t:Thing = new Thing();

            for each(var i:String in _cloneable)
            {
                t[i] = this[i];
            }

            return t;
        }

    }

}

您需要做的就是添加您想要克隆的属性_cloneable

示例使用：

var thing:Thing = new Thing();

thing.x = 15;
thing.y = 10;
thing.val1 = 25;
thing.val2 = "twentyfive";

// Clone initial Thing.
var thing2:Thing = thing.clone();

trace(thing2.x, thing2.y, thing2.val1, thing2.val2); // 15 10 25 twentyfive

Answer 2

我的建议是不要让它太复杂，也不要过度思考。真的没有必要做比这更复杂的事情了。

 public function clone():Thing {
     var t:Thing = new Thing();

     t.x = this.x;
     t.y = this.y;
     t.val1 = this.val1;
     t.val2 = this.val2;

     return t;
 }

如果您的构造函数中有参数。

public function Thing(x:int,y:int) {
    this.x = x;
    this.y = y;
}

public function clone():Thing {
    var t:Thing = new Thing(this.x, this.y);

    t.val1 = this.val1;
    t.val2 = this.val2;

    return t;
}

我确实喜欢另一个答案，它很聪明，但只是设置一些属性会带来很多流失。不要过度思考问题。

Answer 3

您可以使用具有可选参数的构造函数创建一个类。从测试驱动开发和性能角度来看，这是一个很好的实践。