1

注意：这是一个练习，我试图了解事情是如何运作的。

我试图让在 Haskell 中做这样的事情成为可能：

f :: Integer -> Integer
f n = def $ do
  i      <- var n
  while i (>0) $ do
    i      -= lit 1
  return i
-- for now, my program returns n

下面是我的程序。在这一点上，我不明白为什么它不起作用，但由于某种原因，变量没有改变。

import Control.Monad.State


data Lit a = Lit a
type Variable a = State Integer a


def :: Variable (Lit a) -> a
def (State f) = fromLit . fst . f $ 0 

fromLit :: Lit a -> a
fromLit (Lit a) = a

lit :: a -> Lit a
lit l = Lit l

var :: a -> Variable (Lit a)
var v = State $ \x -> (lit v, x)

while :: Lit a -> (a -> Bool) -> Variable () -> Variable ()
while (Lit r) cond act = do
                 if cond r then do
                          _ <- act
                          while (Lit r) cond act
                    -- or act >> while (Lit r) cond act
                 else return ()


op :: (Integer -> Integer -> Integer) -> Lit Integer -> Lit Integer -> Variable ()
op f (Lit a) (Lit b) = State $ \n -> ((), if n == a then f a b else n)
-- that is, if the state is (a) change it to (f a b), else don't change it

(+=) = op (+)
(-=) = op (-)
(*=) = op (*)

请帮助我了解这里出了什么问题以及如何改进代码。谢谢你。

4

1 回答 1

6

不用说，这在 Haskell 中是一件很愚蠢的事情。但是，如果它可以帮助您学习一些东西，我完全赞成尝试愚蠢的事情。

我认为您可能应该退回到一个更简单的问题，并在尝试像这样复杂的事情之前多尝试一下 State monad；从您发布的代码片段中，我怀疑您的直觉有点偏离。

你当然可以做这种事情，但是在 State monad 中处理“任意”类型的变量是很棘手的（它必须有一个固定的状态类型）。您可以使用Dynamicand Proxy;以相对类型安全的方式进行操作 但我认为这可能仍然有点遥不可及。

我们将从存储 Int 类型的变量开始。我不确定State您使用的是哪个单子，但我会使用其中的一个mtl。

import Control.Monad.State
import qualified Data.Map as M
import Data.Maybe

data Var = Var Int
  deriving (Show, Eq, Ord)

data Env = Env {freshVar :: Int, vars :: M.Map Var Int}
  deriving Show

type Imperative a = State Env a

我已经定义了Env跟踪我们“创建”的所有变量的类型，以及一个“新名称”生成器，它只是一个在我们定义变量时不断向上计数的 Int。

lit :: Int -> Imperative Var
lit n = do
    varID <- gets freshVar
    let newVar = Var varID
    modify (\s -> s{freshVar=n+1, vars=(M.insert newVar n (vars s))})
    return newVar

此代码从文字数字创建一个新的“变量”，它通过从环境中获取一个新的变量名称，将其包装在构造函数中，然后将其与提供的值一起存储在环境中来实现。请注意，我们增加了freshVar 数字，因此我们将为下一个文字获得不同的变量id。

getVar :: Var -> Imperative Int
getVar v = gets (fromJust . M.lookup v . vars)

setVar :: Var -> Int -> Imperative ()
setVar v n = modify (\s -> s{vars=M.insert v n (vars s)})

这些是在我们的变量映射中查找变量或设置变量的一些助手。一般不安全的getVar用途；fromJust但如果你只用“lit”定义新变量，那么它就可以正常工作。

op :: (Int -> Int -> Int) -> Var -> Var -> Imperative ()
op f aVar bVar = do
    a <- getVar aVar
    b <- getVar bVar
    setVar aVar (f a b)

(+=) = op (+)
(-=) = op (-)
(*=) = op (*)

要执行您的变异操作版本，我们需要两个变量，查找它们的当前值，执行操作，然后将结果存储到左侧的变量中。

现在我们可以定义while

while :: Imperative Bool -> Imperative () -> Imperative ()
while cond act = do
    continue <- cond
    if continue then act >> while cond act
                else return ()

我们可以接受任何返回布尔值作为条件的命令式语句；如果需要，用户可以在语句中查找变量的状态。我们只需运行语句，如果我们想继续我们act然后递归，否则我们返回。

f :: Int -> Int
f n = run $ do
  i <- lit n
  while ((>0) <$> getVar i) $ do
    one <- lit 1
    i -= one
  getVar i

这有点罗嗦（我们可以简化它，但它会使组合器更复杂）。我们将我们i的值定义为一个新变量n，然后检查它是否大于0条件。在循环体中，我们用值定义一个变量1，然后从变量中减去它i。

循环结束后，我们检查i

run :: Imperative a -> a
run m = evalState m (Env 0 M.empty)

这是run我们上面使用的函数，它只是运行没有定义变量的状态。

如果您尝试一下，您会看到它成功达到零；你可以添加一个跟踪语句来查看它命中了哪些值：

import Debug.Trace
f :: Int -> Int
f n = run $ do
  i <- lit n
  while ((>0) <$> getVar i) $ do
    getVar i >>= traceShowM
    one <- lit 1
    i -= one
  getVar i

>>> f 10
10
9
8
7
6
5
4
3
2
1
0
于 2019-11-22T18:54:07.543 回答