1

我有一个lex文件，里面有我的规则，例如：

PROGRAM           return Parser::PROGRAM;
PROGRAM_END       return Parser::PROGRAM_END;
VARIABLES:        return Parser::VARIABLES;
INSTRUCTIONS:     return Parser::INSTRUCTIONS; 
SKIP              return Parser::SKIP;
.           {
                std::cerr << lineno() << ": ERROR." << std::endl;
                exit(1);
            }

并且当我尝试使用完全编译的（带有yacc文件等）版本时，即使测试文件正确，也仅在测试文件上使用最后一条规则。

例如，这是这些规则的测试文件：

PROGRAM fst
INSTRUCTIONS:
    SKIP
PROGRAM_END

对于这个文件，我只得到：1: ERROR.

为什么会这样，我该如何解决？

4

1 回答 1

1

正如评论中所指出的，几乎可以肯定的PROGRAM是，开始识别为令牌并传递给解析器的情况。然而，在几乎所有情况下，解析器都会立即请求另一个标记，输入序列中的下一个字符是空格，由最后一条规则匹配。该规则打印一条错误消息并调用exit()，终止应用程序。（这通常不是一个好主意，但我想这只是一个测试程序。）这就是您将获得的所有输出。

如果您-d在调用 (f)lex 时指定命令行参数，则会生成一个调试扫描器，它会在扫描器工作时报告扫描器的进度。这是查看扫描仪中正在发生的事情的一种非常简单的方法。Bison 也有调试模式，如野牛手册中所述。这些工具使用起来非常简单，强烈推荐。

例如，这里是一个快速测试台：

%{
#include <iostream>
#include <cstdlib>
class Parser {
  public:
    enum Token {
      PROGRAM = 257,
      PROGRAM_END, VARIABLES, INSTRUCTIONS, SKIP
    };
};
%}
%option batch noyywrap yylineno c++
%%
PROGRAM           return Parser::PROGRAM;
PROGRAM_END       return Parser::PROGRAM_END;
VARIABLES:        return Parser::VARIABLES;
INSTRUCTIONS:     return Parser::INSTRUCTIONS; 
SKIP              return Parser::SKIP;
.                 {
                    std::cerr << lineno() << ": ERROR." << std::endl;
                    exit(1);
                  }
%%
int main() {
  yyFlexLexer lexer{};
  lexer.set_debug(1);
  while(lexer.yylex() != 0) { }
  return 0;
}

和一个示例运行：

$ g++ lex.yy.cc && ./a.out<<<"PROGRAM fst"
--(end of buffer or a NUL)
--accepting rule at line 14("PROGRAM")
--accepting rule at line 19(" ")
1: ERROR.

这清楚地表明扫描仪确实首先生成了PROGRAM令牌，然后才退出空格字符。

于 2019-11-09T18:52:09.213 回答