10

多年来，我的应用程序一直采用一种模式，客户可以“禁用对操作系统的访问”。显然，此功能违背了常规（至少就 Windows 而言），但在某些安装中，我的应用程序是唯一应该对机器操作员可见的程序，并且在这种情况下，这样的功能很有用。

我使用的技术是由几个“层”构建的：

  1. 隐藏任务栏和按钮。
  2. 禁用任务切换。
  3. 禁用我的主表单系统图标。

要禁用我使用的任务栏：

// Get a handle to the taskbar and its button..
Taskbar := FindWindow('Shell_TrayWnd', Nil);
StartButton := FindWindow('Button', Nil);

// Hide the taskbar and button
if Taskbar <> 0 then
  ShowWindow( Taskbar, SW_HIDE );
if StartButton <> 0 then
  ShowWindow( StartButton, SW_HIDE );

// Set the work area to the whole screen
R := Rect( 0,0,Screen.Width,Screen.Height );
SystemParametersInfo(
  SPI_SETWORKAREA,
  0,
  @R,
  0 );

这工作得很好，在 W7 上看起来仍然很好。几年前研究如何禁用任务切换发现了“假装”您的应用程序是屏幕保护程序的唯一技术（除了将您的应用程序重命名为“explorer.exe”并启动它等可怕的事情）：

procedure EnableTaskSwitching( AState : boolean );
// Enables / disables task switching
begin
  SystemParametersInfo(
    SPI_SCREENSAVERRUNNING,
    Cardinal( not AState),
    nil,
    0 );
end;

毫不奇怪，这似乎在 W7 中没有效果（我认为它适用于 XP 等）。有谁知道另一种更好的方法来启用/禁用 Alt-Tab（和其他特殊的 Windows 键）工作？

4

4 回答 4

12

如果找到解决方案：

function LowLevelKeyboardProc(nCode: integer; wParam: WPARAM; lParam: LPARAM):
  LRESULT; stdcall;
type
  PKBDLLHOOKSTRUCT = ^TKBDLLHOOKSTRUCT;
  TKBDLLHOOKSTRUCT = record
    vkCode: cardinal;
    scanCode: cardinal;
    flags: cardinal;
    time: cardinal;
    dwExtraInfo: Cardinal;
  end;

  PKeyboardLowLevelHookStruct = ^TKeyboardLowLevelHookStruct;
  TKeyboardLowLevelHookStruct = TKBDLLHOOKSTRUCT;
const
  LLKHF_ALTDOWN = $20;
var
  hs: PKeyboardLowLevelHookStruct;
  ctrlDown: boolean;
begin

  if nCode = HC_ACTION then
  begin

    hs := PKeyboardLowLevelHookStruct(lParam);
    ctrlDown := GetAsyncKeyState(VK_CONTROL) and $8000 <> 0;
    if (hs^.vkCode = VK_ESCAPE) and ctrlDown then
      Exit(1);
    if (hs^.vkCode = VK_TAB) and ((hs^.flags and LLKHF_ALTDOWN) <> 0) then
      Exit(1);
    if (hs^.vkCode = VK_ESCAPE) and ((hs^.flags and LLKHF_ALTDOWN) <> 0) then
      Exit(1);
    if (hs^.vkCode = VK_LWIN) or (hs^.vkCode = VK_RWIN) then
      Exit(1);

  end;

  result := CallNextHookEx(0, nCode, wParam, lParam);

end;

procedure TForm1.FormShow(Sender: TObject);
begin
  SetWindowsHookEx(WH_KEYBOARD_LL, @LowLevelKeyboardProc, 0, 0);
end;

这会禁用（如您所见！）

  • Ctrl+Esc（显示开始菜单）
  • Alt+Tab（任务切换）
  • Alt+Esc（任务切换）
  • 赢（显示开始菜单）
  • Win+Tab（3D任务切换）
  • Win+D、Win+M、Win+空格、Win+箭头、Win+P、Win+U、Win+E、Win+F、Win+数字、...
  • 几乎任何组合，包括 Windows 键（但不是全部，例如 Win+L）
于 2011-05-01T19:09:19.007 回答
6

正如大卫所指出的，这被称为“信息亭模式”。可以在 About.com 上找到几篇好文章（第 1部分和第 2 部分）。

于 2011-05-01T21:16:29.290 回答
1

您可以将Windows Embedded Standard 7打包成真正的信息亭模式。

于 2011-05-02T07:03:35.310 回答
0

dWinLock also provides a solution. IIRC, they install a service that can stop Ctrl+Alt+Del.

于 2011-05-02T09:00:10.187 回答