1

所以我有一个家庭作业，我给出了以下代码：

numeral(0).
numeral(succ(X)) :- numeral(X).
numeral(X+Y) :- numeral(X), numeral(Y).

add(0,X,X).
add(succ(X),Y,succ(Z)) :- add(X,Y,Z).

我要定义一个序言谓词 add2(X,Y,Z) ，它将产生例如以下输出

% Exercise 1 Test Cases (for copy-paste to the REPL
%% 1. add2(succ(0)+succ(succ(0)), succ(succ(0)), Z).
%%    >>>> Z = succ(succ(succ(succ(succ(0)))))
%%
%% 2. add2(0, succ(0)+succ(succ(0)), Z).
%%    >>>> Z = succ(succ(succ(0)))
%%
%% 3. add2(succ(succ(0)), succ(0)+succ(succ(0)), Z).
%%    >>>> Z = succ(succ(succ(succ(succ(0)))).
%%
%% 4. add2(succ(0)+succ(0), succ(0+succ(succ(0))), Z).
%%    >>>> Z = succ(succ(succ(succ(succ(0))))).

所以过去几天我一直在研究这个问题，并在解决方案上做出了合理的尝试。这是我到目前为止一直在尝试的：

% Exercise 1 Solution
add2(X,Y,Z):- add(X,Y,Z).
add2(A+B,Y,Z):- add2(A,B,X), add2(X,Y,Z).
add2(X,A+B,Z):- add2(A,B,Y), add2(X,Y,Z).

现在，上面的代码对于提供的前 3 个输入非常有效。我很难考虑 prolog 如何解释最后一个，以及如何利用它。

这就是我认为可能有效的方法。

add2(X, succ(A+B), Z):- add2(A,B,Y), add2(X, succ(Y), Z).

我的想法是，解释器会将诸如 succ(0+succ(...)) 之类的输入识别为 succ(A+B)，然后上述规则将能够解析 0+succ(. ..) 进入 succ(...) 。我从 SWI-PL REPL 收到的输出很简单：

Z = succ(succ(succ(0+succ(succ(0)))))

我进行的另一次尝试如下：

add2(X,succ(0+succ(Y), Z)):- add2(X,succ(Y),Z).

但是，这会产生与以前相同的输出。我不确定为什么上述两次尝试似乎对我不起作用，虽然我做了其他猜测，但上述两个或其他谓词或多或少有随机变化，如果我通过这种方法成功了，我会可能在不了解我在做什么的情况下获得了正确的答案。

我使用 SWI-PL 作为我的 prolog 发行版。

4

1 回答 1

1

我认为在这里使用辅助谓词可能有助于解决问题。辅助函数会将用 和 的级联表示的数字转换succ(…)为… + …统一的样式（仅限succ(…)）。

因此，我们可以实现如下功能：

normsucc(0, 0).
normsucc(succ(X), succ(NX)) :-
    normsucc(X, NX).
normsucc(X+Y, NXY) :-
    normsucc(X, NX),
    normsucc(Y, NY),
    add(NX, NY, NXY).

那么我们可以利用normsucc来计算总和：

add2(X, Y, Z) :-
    normsucc(X, NX),
    normsucc(Y, NY),
    add(NX, NY, Z).

或更简单，就像@false建议的那样：

add2(X, Y, Z) :-
    normsucc(X+Y, Z).
于 2019-10-12T20:01:50.327 回答