0

我创建了一个程序来显示员工的最高和最低工资的 n 个数。如果我给出 5 作为输入，则查询将为我提供 5 个员工的最高和最低工资。

对于上述场景，我创建了一个包含两列的对象，如下所示

create type vrec as object(
empno number,
sal number
);
/

然后我在对象类型的帮助下创建了嵌套表，这样我就可以使用嵌套表作为输出参数来一次返回所有行。

create type vrec_type is table of vrec;
/

创建数据类型后，我创建了一个如下所示的过程

create or replace procedure pro_first_last(input in number,salary out vrec_type)
is
begin
select empno,sal BULK COLLECT INTO salary from (
select empno,sal from  
(select empno,sal,rank() over(order by sal asc) min_sal from emp5 where sal is not null) where min_sal <= 5
union all
select empno,sal from 
(select empno,sal,rank() over(order by sal desc) max_sal from emp5 where sal is not null) where max_sal <= 5);
for i in salary.first..salary.last
loop
dbms_output.put_line(salary(i).empno);
end loop;
end;
/

当我编译上述过程时，我得到的值不够。我还创建了具有两列的对象，并且在 select 语句中也只返回了两列。有人可以对此进行审查并帮助我或提供一些替代解决方案。

4

1 回答 1

1

您直接将empno, sal值添加到salary（vrec_type对象，它可以只取对象类型的值vrec）

您需要创建objectofvrec然后将其添加到salary如下：

create or replace procedure pro_first_last(input in number,salary out vrec_type)
is
begin
  select vrec(empno,sal) -- change in this line
         BULK COLLECT INTO salary from ( 
    select empno,sal from  
      (select empno,sal,rank() over(order by sal asc) min_sal from emp5 where sal is not null) where min_sal <= 5
    union all
    select empno,sal from 
     (select empno,sal,rank() over(order by sal desc) max_sal from emp5 where sal is not null) where max_sal <= 5);
    for i in salary.first..salary.last
      loop
        dbms_output.put_line(salary(i).empno);
    end loop;
end;

干杯！！

于 2019-09-25T05:12:44.823 回答