0

我想知道如何在创建的列表中获得某个对象的位置。可以说它就像一个图形列表，您可以在其中单击对象。假设您右键单击一个对象并单击“刷新”，我如何获取该对象的位置，以便在刷新整个列表后（由于某种原因用清除列表刷新）我回到列表中的相同位置? 这是如果列表说 1000 个对象长，这使得在刷新后尝试向下滚动到同一位置很麻烦。

该代码使用 Tobject 但我可以做类似 position:=integer(TObject."pointerinfo???"); 之后，当程序刷新时，例如将视图的位置设置为指针，如 currentview(pointer) 或类似的东西？

实际上它不必是同一个对象，但列表的相同“视图”会更好。

提前致谢

4

2 回答 2

5

如果刷新将再次以相同的顺序为您提供相同的列表，那么不要费心去发现有关该对象的任何信息。只需存储列表控件的ItemIndex属性，该属性指示当前选定的项目。

如果刷新可能会给你一个不同的列表，那么你想要的对象之后可能不在同一个位置，所以仅仅记住ItemIndex是不够的。在这种情况下，您需要找到对象的新位置。如何做到这一点取决于列表控件的功能以及它如何公开与每个位置关联的对象。TListBox例如，如果您有一个，则该Items属性是一个TStrings对象，您可以检查Objects数组的每个值，直到找到所需的对象。存储对象引用的值，然后搜索它。像这样的东西：

procedure Refresh;
var
  CurrentSelection: TObject;
  ObjectPosition: Integer;
  i: Integer;
begin
  if List.ItemIndex >= 0 then
    CurrentSelection := List.Strings.Objects[List.ItemIndex]
  else
    CurrentSelection = nil;
  RefreshList;
  ObjectPosition := -1;
  if Assigned(CurrentSelection) then begin
    for i := 0 to Pred(List.Count) do begin
      if List.Strings.Objects[i] = CurrentSelection then begin
        ObjectPosition := i;
        break;
      end;
    end;
  end;
  if ObjectPosition = -1 then
    // Object isn't in refreshed list
  else
    // It is.
end;

最后一种可能性是，刷新实际上根本不会保留相同的对象。所有先前的对象都被销毁，并生成一个新的对象列表。在这种情况下，您必须记住原始对象的某些识别特征，以便找到代表相同事物的新对象。像这样的东西：

var
  CurrentObject, Person: TPerson;
  CurrentName: string;
  i, ObjectPosition: Integer;
begin
  if List.ItemIndex >= 0 then begin
    CurrentObject := List.Strings.Objects[List.ItemIndex] as TPerson;
    CurrentName := CurrentObject.Name;
  end else
    CurrentName = '';
  RefreshList;
  ObjectPosition := -1;
  if CurrentName <> '' then begin
    for i := 0 to Pred(List.Count) do begin
      Person := List.Strings.Objects[i] as TPerson;
      if Person.Name = CurrentName then begin
        ObjectPosition := i;
        break;
      end;
    end;
  end;
  if ObjectPosition = -1 then
    // Object isn't in refreshed list
  else
    // It is.
end;

在所有这些情况下，您应该意识到对象在列表中的位置实际上并不是对象的属性。相反，它是列表的一个属性，这就是为什么列表在所有代码中比对象发挥更大的作用。实际上没有任何“指针信息”可以从对象中获取，因为对象通常不知道它甚至在列表中，所以它肯定不会知道它相对于列表中所有其他项目的位置。

确定对象在列表中的位置后，您需要将其滚动到视图中。对于TListBox，一个简单的方法是设置它的TopIndex属性：

List.TopIndex := ObjectPosition;

最后，如果您实际上根本不关心当前对象，而只是想恢复当前滚动位置，那就更容易了：

procedure Refresh;
var
  CurrentPosition: Integer;
begin
  CurrentPosition := List.TopIndex;
  RefreshList;
  List.TopIndex := CurrentPosition;
end;
于 2011-04-26T13:12:14.577 回答
1

所以我想在我得到的帮助下，我回答了我自己的问题。我所做的是编写了一些获取列表视图的 x 和 y 位置的内容，然后在使用 clearlist 进行刷新后，我使用滚动功能返回到相同的功能。我的程序看起来像这样。

procedure Refresh(Sender: TObject);
var
  horzpos:integer;
  vertpos:integer;
begin
    horzpos:=ListView1.ViewOrigin.X;
    vertpos:=ListView1.ViewOrigin.Y;
    RefreshListView(ListView1); //A function that refreshes the list and clears it
    ListView1.Scroll(horzpos, vertpos);
 end;

也许我应该早点说它是一个列表视图类型，并且我想在“clearlist”之后再次回到相同的位置。

感谢所有的帮助，这个社区摇滚！

于 2011-04-27T12:46:27.430 回答