1

我正在使用几何着色器从 GL_POINTS 生成立方体

#version 150 core

layout(points) in;
layout(triangle_strip, max_vertices = 18) out;

in vec3 g_col[];

out vec3 f_col;

uniform mat4 transform;

void main()
{
    f_col = g_col[0];

    float s = gl_in[0].gl_PointSize * 0.5;

    vec4 c = gl_in[0].gl_Position;

    // Bottom

    gl_Position = transform * (c + vec4 (-s, -s, -s, 0));
    EmitVertex();

    gl_Position = transform * (c + vec4 (+s, -s, -s, 0));
    EmitVertex();

    gl_Position = transform * (c + vec4 (-s, +s, -s, 0));
    EmitVertex();

    gl_Position = transform * (c + vec4 (+s, +s, -s, 0));
    EmitVertex();

    // Far

    gl_Position = transform * (c + vec4 (-s, +s, +s, 0));
    EmitVertex();

    gl_Position = transform * (c + vec4 (+s, +s, +s, 0));
    EmitVertex();

    // Top

    gl_Position = transform * (c + vec4 (-s, -s, +s, 0));
    EmitVertex();

    gl_Position = transform * (c + vec4 (+s, -s, +s, 0));
    EmitVertex();

    // Near

    gl_Position = transform * (c + vec4 (-s, -s, -s, 0));
    EmitVertex();

    gl_Position = transform * (c + vec4 (+s, -s, -s, 0));
    EmitVertex();

    EndPrimitive();

    // Left

    gl_Position = transform * (c + vec4 (-s, -s, -s));
    EmitVertex ();

    gl_Position = transform * (c + vec4 (-s, +s, -s));
    EmitVertex ();

    gl_Position = transform * (c + vec4 (-s, -s, +s));
    EmitVertex ();

    gl_Position = transform * (c + vec4 (-s, +s, +s));
    EmitVertex ();

    EndPrimitive ();
}

EndPrimitive如果我在第一个（注释之前）之后删除代码// Left，这会正确地在立方体周围绘制一条带，使侧面不加盖。

如果我尝试绘制一个新的三角形条来覆盖侧面，那么随后的四个EmitVertex调用中的每一个都会出现此错误：

error C1067: too little data in type constructor

根据这个文件

GS 定义了这些顶点输出代表什么类型的图元。GS 也可以通过调用 EndPrimitive() 函数来结束一个原语并开始一个新的原语。这不会发出顶点。

为了从 GS 中写入两个独立的三角形，您必须使用 EmitVertex() 为前三个顶点编写三个单独的顶点，然后调用 EndPrimitive() 来结束条带并开始一个新的条带。然后你用 EmitVertex() 再写三个顶点。

我究竟做错了什么？

4

1 回答 1

2

在工作部分：

gl_Position = transform * (c + vec4 (+s, -s, -s, 0));

在非工作部分：

gl_Position = transform * (c + vec4 (-s, -s, -s));

vec4正如错误消息告诉您的那样，构造函数需要四个组件。

于 2019-08-28T23:27:20.630 回答