2

我在一个并不真正支持子元素的数据库中工作。为了解决这个问题，我们一直}}在值字符串中使用波浪括号来表示子元素之间的分隔。当我们导出到 xml 时，它看起来像这样：

<geographicSubject>
   <data>Mexico }} tgn }} 123456</data>
   <data>Mexico City }} tgn }} 7891011</data>
   <data>Main Street }} tgn }} 654321</data>
</geographicSubject>

我的问题：如何创建我们的 XSLT 以便将字符串拆分<data>为单独的唯一命名的子元素，如下所示：

<data>
   <location>Mexico</location>
   <source>tgn</source>
   <id>123456</id>
</data>

第一个}}表示“source”的开始，第二个}}表示“id”的开始。感谢任何愿意提供帮助的人！

4

1 回答 1

4

编写一个分词器：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:e="http://localhost">
    <e:e>location</e:e>
    <e:e>source</e:e>
    <e:e>id</e:e>
    <xsl:variable name="vElement" select="document('')/*/e:*"/>
    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
    </xsl:template>
    <xsl:template match="data/text()" name="tokenizer">
        <xsl:param name="pString" select="string()"/>
        <xsl:param name="pPosition" select="1"/>
        <xsl:if test="$pString">
            <xsl:element name="{$vElement[$pPosition]}">
                <xsl:value-of
                 select="normalize-space(
                            substring-before(concat($pString,'}}'),'}}')
                         )"/>
            </xsl:element>
            <xsl:call-template name="tokenizer">
                <xsl:with-param name="pString"
                                select="substring-after($pString,'}}')"/>
                <xsl:with-param name="pPosition" select="$pPosition + 1"/>
            </xsl:call-template>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>

输出：

<geographicSubject>
    <data>
        <location>Mexico</location>
        <source>tgn</source>
        <id>123456</id>
    </data>
    <data>
        <location>Mexico City</location>
        <source>tgn</source>
        <id>7891011</id>
    </data>
    <data>
        <location>Main Street</location>
        <source>tgn</source>
        <id>654321</id>
    </data>
</geographicSubject>
于 2011-04-22T15:42:51.190 回答