0

我正在通过 APEX 使用 ORDS (v18.3) 创建一个 API，我需要能够为同一参数传递多个值，例如：

https://server-url/resource?id=1&id=2

这是第三方要求，无法更改。

当我尝试使用这样的 URL 时，只有第一个参数被传递，第二个参数被删除。

是否可以使用 ORDS 做我需要的事情？

4

2 回答 2

3

我有一个类似的问题，我通过简单地处理查询字符串来解决。

创建了一个函数：

create or replace function array_from_oldschool(p_query_string in varchar2, p_key in varchar2) return apex_t_varchar2 is
  l_ret     apex_t_varchar2 := apex_t_varchar2();
  l_usenext boolean := false;
  l_isval   boolean := false;
  l_arr     apex_t_varchar2;
begin
  l_arr := apex_string.split(p_query_string, '\s*[=&]\s*');
  for i in 1 .. l_arr.count loop
    if l_usenext = true and l_isval = true then
      l_ret.extend;
      l_ret(l_ret.count) := l_arr(i);
      l_usenext := false;
    end if;

    if l_arr(i) = p_key and l_isval = false then
      l_usenext := true;
    end if;

    l_isval := not (l_isval);
  end loop;

  return l_ret;
end;

测试：创建一个 ORDS GET 服务，输入 PL/SQL

declare
  l_arr apex_t_varchar2;
begin
  l_arr := array_from_oldschool(p_query_string => owa_util.get_cgi_env('QUERY_STRING'), p_key => 'id');

  for i in 1 .. l_arr.count loop
    htp.prn(l_arr(i) || ' <br>');
  end loop;
end;

测试它： GET testme/old-school?id=1&id=2&id=10&id=100&id=99

输出是：

1
2
10
100
99

您将需要更改一些代码，从使用 owa_util.ident_arr 到 Varchar2 的 TABLE，如 apex_T_varchar2。但它应该是最小的。

问候奥拉维尔

* 编辑 * 这个函数更好，因为如果查询字符串有空参数（即 val=&val2=&val4=），另一个函数会出错

create or replace function query_string_array(p_key in varchar2) return apex_t_varchar2 is
  l_query_string apex_t_varchar2;
  l_return       apex_t_varchar2 := apex_t_varchar2();
begin
  l_query_string := apex_string.split(owa_util.get_cgi_env('QUERY_STRING'), '&');
  for i in 1 .. l_query_string.count loop
    if l_query_string(i) like p_key || '=%' then
      if replace(l_query_string(i), p_key || '=', '') is not null then
        l_return.extend;
        l_return(l_return.count) := replace(l_query_string(i), p_key || '=', '');
      end if; --don't add empty/null values
    end if;
  end loop;
  return l_return;
end;
于 2019-08-30T13:18:09.377 回答
0

据我所知，您可以传递任意数量的值，但它们都应该属于同一个参数并用冒号分隔。在你的情况下，那将是

https://server-url/resource?id=1:2

这也意味着您必须在之后以某种方式“拆分”它们以获得单独的值。

当我从 Apex 调用报告（由 Oracle Reports 开发）时，我使用了它。在其After 参数表单触发器中拆分这些值不是问题，但是 - 我不知道您是否可以这样做。

希望有人会比我更了解。

于 2019-08-07T10:31:42.543 回答