1

在 firemonkey (RAD Studio 10.3) 中，我正在使用连接到数据库的 TStringGrid，并且我想更改特定列的文本对齐方式。我怎样才能做到这一点？在 TextSettings 属性中更改 HorzAlign 会更改所有列的对齐方式。

我尝试了此页面中建议的解决方案，但没有奏效！在较新版本的 Firemonkey 中，以下解决方案代码会导致错误。

type TSpecificColumn = class(TColumn)
protected
  function CreateCellControl: TStyledControl;override;
end;

TColumn 类中没有 CreateCellControl 函数可以被覆盖！这是我得到的错误：

在基类中找不到方法 CreateCellControl。

4

2 回答 2

3

在OnDrawColumnCell和/或OnDrawColumnHeader事件中，您可以使用 aTTextLayout来达到目的。如以下示例所示，使用三种不同的对齐方式绘制单元格。绘制标题时也可以应用相同的方法：

uses
  ...
  fmx.textlayout;


procedure TForm11.Grid1DrawColumnCell(Sender: TObject; const Canvas: TCanvas;
  const Column: TColumn; const Bounds: TRectF; const Row: Integer;
  const Value: TValue; const State: TGridDrawStates);
var
  tl: TTextLayout;
  rf: TRectF;    // added
begin
  tl := TTextLayoutManager.DefaultTextLayout.Create;
  try
    tl.BeginUpdate;
    try
      // added from here
      rf := Bounds;
      InflateRect(rf, -2, -2);
      if (TGridDrawState.Selected in State) or
         (TGridDrawState.Focused in State) or
         (TGridDrawState.RowSelected in State)
      then
        Canvas.Fill.Color := TAlphaColors.LightBlue
      else
        Canvas.Fill.Color := TAlphaColors.White;

      Canvas.FillRect(rf, 0, 0, [], 1);
      // added until here

      tl.TopLeft := Bounds.TopLeft;
      tl.MaxSize := PointF(Column.Width, Column.Height);
      tl.Font.Size := 15;
      tl.Text := 'Some text'; // Value
      case Column.Index of
        0: tl.HorizontalAlign := TTextAlign.Leading;
        1: tl.HorizontalAlign := TTextAlign.Center;
        2: tl.HorizontalAlign := TTextAlign.Trailing;
      end;
    finally
      tl.EndUpdate;
    end;
    tl.RenderLayout(Canvas);
  finally
    tl.Free;
  end;
end;

在此处输入图像描述

TTextLayout还有许多其他有用的选项和属性，所以我建议看一下文档。

于 2019-07-20T12:32:39.357 回答
0

除了已经确定的更改之外InflateRect(rf, 0, 0)，为了允许正确显示现有数据：

改变

tl.Text := 'Some text'; // Value line

到

tl.Text := [StringGrid name property].Cells[Column.Index,Row];

这对我有用。

于 2020-06-13T03:05:08.990 回答