2

我的期望是它打印一个字符串，但什么都没有打印出来。当我把字符串变短时，它有时会起作用，当我再次把它们变长时，它有时会起作用。

我不知道为什么这不起作用。

有人可以帮我吗？谢谢。

我正在使用的汇编代码是：

（Emacs 23、Ubuntu 10.10、nasm、VirtualBox OSE）

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
org 0x7c00
bits 16
str:
    db "Some say the world will end in fire",10,13
    db "Some say in ice",10,13
    db "From what I've tasted of desire",10,13
    db "I hold with those who favor fire",10,13
    db "But if I had to perish twice,",10,13
    db "I think I know enough of hate",10,13
    db "To say that for destruction ice",10,13
    db "is also great and would suffice."
    db "Robert Frost - Fire and Ice"
    db 0
start:
    xor ax,ax
    mov ds,ax
    mov es,ax
    mov si, str
    xor bx,bx
    mov ah, 0x0e
print:
    lodsb   ;al = current char
    cmp al, 0
    je end
    int 0x10
    jmp print
end:    
    cli
    hlt

    times 510 - ($-$$) db 0
    dw 0xAA55
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
4

2 回答 2

9

因为它在指令处开始执行代码7c00。不幸的是，这就是您拥有字符串的地方。

您应该在该字符串前面加上一条jmp指令，以便它跳转到start.

这通常是一个短暂的跳跃EB xx，然后是一个 NOP 90。一些 BIOS' 可能会坚持这种形式，即使它对处理器来说并不重要。

换句话说，你会寻找类似的东西：

org 0x7c00
bits 16
realstart:
    jmp short start
    nop
str:
    db "Some say the world will end in fire",10,13
    :
    db "Robert Frost - Fire and Ice"
    db 0
start:
    xor  ax,ax
    :

请记住，短跳受限于它可以走的距离，大约 +/-128 字节，因此您的字符串大小必然会受到限制。如果您的 BIOS 不需要该EB xx 90格式，则可以进行常规跳转。

您可以尝试的另一件事是将整个字符串移动到hlt指令之后：

org 0x7c00
bits 16
start:
    xor  ax,ax
    :
end:    
    cli
    hlt
str:
    db "Some say the world will end in fire",10,13
    :
    db "Robert Frost - Fire and Ice"
    db 0

但是，同样，这取决于您的 BIOS 在开始时不需要jmp/nop组合。

于 2011-04-18T07:02:49.560 回答
1

验证 paxdiablo 和 Igor Skochinsky 是否正确的一个好方法是将文本字符串放入文件中，然后通过反汇编程序运行它。正确打印的较短字符串应该反汇编成一个不会伤害任何东西的代码字符串。失败的较短字符串和较长的字符串将包含非法指令、跳转或调用指令，甚至在末尾有一个 2 或 3 字节的指令，它会在"xor ax,ax"代码开头吃掉指令的操作码.

于 2011-05-16T15:52:12.103 回答