oracle - Oracle (10g) 相当于 DATEADD(weekday, -3, GETDATE())

Question

我正在寻找相当于以下内容的 Oracle (10g)：

DATEADD(weekday, -3, GETDATE())

来自 T-SQL (SQL Server)。这会从当前日期减去 3 个工作日。我不关心假期或类似的事情（我可以​​自己截断时间部分）。只排除周末就可以了。

Answer 1

它可以在没有 PL/SQL 函数的情况下完成。只需根据星期几减去不同的天数：

select trunc(sysdate) - case to_char(sysdate, 'D')
                        when '4' then 3 -- thursday minus 3 days
                        when '5' then 3 -- friday minus 3 days
                        when '6' then 4 -- saturday minus 4 days
                        else 5          -- all other days minus 5 days
                        end
from dual;

当您必须在例如 12 天前执行此操作时，它看起来像：

select trunc(sysdate) - case to_char(sysdate, 'D')
                        when '1' then 18 -- mondays minus 18 days (incl. 3 weekends)
                        when '2' then 18 -- tuesdays minus 18 days (incl. 3 weekends)
                        when '6' then 17 -- saturdays minus 17 days (incl. 2 weekends and a saturday)
                        else 16          -- all others minus 16 days (incl. 2 weekends)
                        end
from dual;

请注意，星期几取决于数据库的 NLS_TERRITORY（在美国，第 1 天是星期日，在大多数其他国家，第 1 天是星期一）。

Answer 2

看起来您需要创建一个 UDF。

CREATE OR REPLACE FUNCTION business_date (start_date DATE, 
days2add NUMBER) RETURN DATE IS
 Counter NATURAL := 0;
 CurDate DATE := start_date;
 DayNum POSITIVE;
 SkipCntr NATURAL := 0;
 Direction INTEGER := 1;  -- days after start_date
 BusinessDays NUMBER := Days2Add;
BEGIN
  IF Days2Add < 0 THEN
    Direction := - 1; -- days before start_date
    BusinessDays := (-1) * BusinessDays;
  END IF;

  WHILE Counter < BusinessDays LOOP
    CurDate := CurDate + Direction;
    DayNum := TO_CHAR( CurDate, 'D');

    IF DayNum BETWEEN 2 AND 6 THEN
      Counter := Counter + 1;
    ELSE
      SkipCntr := SkipCntr + 1;
    END IF;
  END LOOP;

  RETURN start_date + (Direction * (Counter + SkipCntr));
END business_date;

由拉里·本顿（Larry Benton）提供，来自这里。