1

我有一个木偶模块 A。在该模块中，我有一个服务重新启动以更改文件。

class A::test1 { 
  include ::corednsclient
  service { 'sshd':
    ensure => running,
    enable => true,
  }
}

现在，我有一个不同的 puppet 模块 B。在该模块中，我还必须重新启动相同的服务才能更改另一个文件。

现在，问题是我得到以下信息：

Duplicate declaration error

当我在做 /opt/puppetlabs/bin/puppet 应用 --modulepath=/abc xyz/site.pp

如果我作为puppet apply -e 'include moduleA' 和 puppet apply -e 'include moduleB'独立运行每个模块，两者都可以正常工作。但是 puppet apply global 似乎失败了。

任何帮助将不胜感激！

Error: Evaluation Error: Error while evaluating a Resource Statement,
 Duplicate declaration: Service[sshd] is already declared in file 
 /export/content/ucm/puppet/modules/coresshd/manifests/configure.pp:28; cannot
 redeclare at 
 /export/content/ucm/puppet/modules/corednsclient/manifests/daemon_reload.pp:10 at 
 /export/content/ucm/puppet/modules/corednsclient/manifests/daemon_reload.pp:10:3 on 
 node lor1-0002276.int.xxx.com .
4

1 回答 1

4

是的，这很正常。Puppet 只允许资源声明一次。一般来说，如果你有这样的代码：

class aaa {
  notify { 'xxx': message => 'yyy' }
}

class bbb {
  notify { 'xxx': message => 'yyy' }
}

include aaa
include bbb

Puppet 应用它，您将看到如下错误：

Error: Evaluation Error: Error while evaluating a Resource Statement,
 Duplicate declaration: Notify[xxx] is already declared at (file: ...test.pp, 
 line: 2); cannot redeclare (file: ...test.pp, line: 6) (file: ...test.pp, line: 6,
 column: 3) on node ...

解决方法

解决方案 1 重构，使两个类都继承第三个类

通常，解决此问题的最佳方法是重构您的代码，以便有一个包含重复资源的第三个类，而其他类包括使用该include函数的类，如下所示：

class ccc {
  notify { 'xxx': message => 'yyy' }
}

class aaa {
  include ccc
}

class bbb {
  include ccc
}

include aaa
include bbb

这很好用。

请注意，这仅有效，因为该include函数可以被多次调用，这与资源声明不同 - 也与类似资源的类声明不同。

你可以在这里阅读更多关于“include-like v resource-like class declarations”的信息。

解决方案 2 使用虚拟资源

您还可以使用虚拟资源。像这样重构：

class ccc {
  @notify { 'xxx': message => 'yyy' }
}

class aaa {
  include ccc
  realize Notify['xxx']
}

class bbb {
  include ccc
  realize Notify['xxx']
}

include aaa
include bbb

另一个优点是您可以使用资源收集器并从一组虚拟资源中仅选择特定资源，如下所示：

class ccc {
  @notify { 'ppp': message => 'xxx' }
  @notify { 'qqq': message => 'yyy' }
  @notify { 'rrr': message => 'zzz' }
}

class aaa {
  include ccc
  Notify <| message == 'xxx' |>
}

class bbb {
  include ccc
  Notify <| message == 'xxx' or message == 'yyy' |>
}

include aaa
include bbb

如果您在这里不需要此功能，就像出现的情况一样，您可能应该使用第一个建议。

解决方案 3 使用确保资源

另一个选项是ensure_resourcesstdlib 中的函数：

class aaa {
  ensure_resources('notify', {'xxx' => {'message' => 'yyy'}})
}

class bbb {
  ensure_resources('notify', {'xxx' => {'message' => 'yyy'}})
}

include aaa
include bbb

解决方案 4 使用定义

从历史上看，这是强烈建议不要使用的，尽管文档没有提到任何不使用它的理由。可以这样使用defined：

class aaa {
  if ! defined(Notify['xxx']) {
    notify { 'xxx': message => 'yyy' }
  }
}

class bbb {
  if ! defined(Notify['xxx']) {
    notify { 'xxx': message => 'yyy' }
  }
}

include aaa
include bbb

这样，只有当资源不存在时，才会将资源添加到目录中。

于 2019-06-20T11:02:29.547 回答