0

我有一个将数据库表作为参数的线程，我遇到了一个问题，我无法同时写入该数据库表。

TMyThread 的 1 个实例可以有一个 'Member' 的 db 表，而另一个可能有 'Staff' 但是可能有两个线程打开同一个表的情况。

因此，我需要将代码包装在一个关键部分（或类似部分）中，但我不想要像几个关键部分（fMemberTable，fStaffTable）这样的脏东西......

begin
    if fDBTable = 'Member' then
        fMemberTable.Enter
    else if fDbTable = 'Staff' then
    ....

我们有 8 张桌子，所以会变得凌乱有什么办法吗？

TCricalSection(fMemberTable).Enter; 还是某种易于“扩展”和使用的方法？

围绕该函数的一个关键部分没有意义，因为我不想阻止其他表....

4

2 回答 2

2

你可以做：

TMonitor.Enter(fMemberTable);
try
  // Do your stuff
finally TMonitor.Exit(fMemberTable);
end;

请注意，这是一个 SPIN LOCK，而不是真正的关键部分。如果您不会发生很多冲突，这非常实用，但如果线程定期相互阻塞，您可能希望退回到临界区。根据定义，自旋锁是忙等待锁。

但我不确定 Delphi 的哪个版本引入了这一点，并且您没有特定于版本的标签。

于 2011-04-14T09:13:59.373 回答
0

您可以使用关键部分列表，例如，本单元中定义的 My class：

interface
uses Classes, SyncObjs;

type
  { TCriticalSectionList by jachguate }
  { http://jachguate.wordpress.com }
  TCriticalSectionList = class
  private
    FCSList: TThreadList;
    FNameList: TStringList;
    function GetByName(AName: string): TCriticalSection;
  public
    constructor Create();
    destructor Destroy(); override;
    property ByName[AName: string]: TCriticalSection read GetByName; default;
  end;

  function CSList: TCriticalSectionList;

implementation
uses SysUtils;

{ TCriticalSectionList }

constructor TCriticalSectionList.Create;
begin
  inherited;
  FCSList := TThreadList.Create;
  FNameList := TStringList.Create;
end;

destructor TCriticalSectionList.Destroy;
var
  I: Integer;
  AList: TList;
begin
  AList := FCSList.LockList;
  for I := AList.Count - 1 downto 0 do
    TCriticalSection(AList[I]).Free;
  FCSList.Free;
  FNameList.Free;
  inherited;
end;


function TCriticalSectionList.GetByName(AName: string): TCriticalSection;
var
  AList: TList;
  AIdx: Integer;
begin
  AList := FCSList.LockList;
  try
    AName := UpperCase(AName);
    AIdx := FNameList.IndexOf(AName);
    if AIdx < 0 then
    begin
      FNameList.Add(AName);
      Result := TCriticalSection.Create;
      AList.Add(Result);
    end
    else
      Result := AList[AIdx];
  finally
    FCSList.UnlockList;
  end;
end;

var
  _CSList: TCriticalSectionList;

function CSList: TCriticalSectionList;
begin
  if not Assigned(_CSList) then
    _CSList := TCriticalSectionList.Create;
  Result := _CSList;
end;

initialization
  _CSList := nil;
finalization
  _CSList.Free;
end.

该类基本上定义了一个关键部分列表，可通过“名称”访问。当您第一次请求特定名称的关键部分时，该关键部分会自动为您创建。您必须访问此类的单个实例，使用提供的 CSList 函数。

当列表的实例被销毁时，所有临界区都被销毁，例如，“默认”实例在应用程序结束时被销毁。

您可以编写如下示例的代码：

begin
  CSList[fDBTable].Enter;
  try
    DoStuff;
  finally
    CSList[fDBTable].Leave;
  end;
end;

享受。

于 2011-04-14T23:34:26.190 回答