0

我有一个看起来像这样的xml，

<Parent> Running text with marked up entities like 
  <Child>Entity1</Child> 
 and, text in the middle too, and
  <Child> Entity2 </Child>
</Parent>

在渲染父级时，我必须保留换行符和缩进，而且还要对每个子标记应用突出显示模板。

现在，当我在变量中捕获父标记的内容以在 XSL 中进行一些字符串处理时，我丢失了底层 xml 结构并且无法将突出显示模板应用于子项。

然而，我想不出任何其他方法来保留父标记中包含的文本的换行符和缩进。

有任何想法吗？

4

2 回答 2

0

这个样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:preserve-space elements="*"/>
    <xsl:template match="Parent">
        <div>
            <xsl:apply-templates mode="preserve"/>
        </div>
    </xsl:template>
    <xsl:template match="text()" mode="preserve" name="split">
        <xsl:param name="pString" select="."/>
        <xsl:choose>
            <xsl:when test="contains($pString,'&#xA;')">
                <xsl:value-of select="substring-before($pString,'&#xA;')"/>
                <br/>
                <xsl:call-template name="split">
                    <xsl:with-param name="pString"
                     select="substring-after($pString,'&#xA;')"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$pString"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
    <xsl:template match="Child" mode="preserve">
        <b>
            <xsl:apply-templates mode="preserve"/>
        </b>
    </xsl:template>
</xsl:stylesheet>

输出：

<div> Running text with marked up entities like<br/> <b>Entity1</b><br/> and, text in the middle too, and<br/> <b> Entity2 </b><br/></div>

呈现为：

运行带有标记实体的文本，例如
Entity1
和中间的文本，以及
Entity2


编辑：更好的例子只保留空白文本节点。

于 2011-04-13T14:57:34.183 回答
0

您没有显示任何代码，这使得您很难说出您做错了什么，但是可以解释所描述症状的一个常见错误是编写

<xsl:variable name="x">
  <xsl:value-of select="some/node/path"/>
</xsl:variable>

当你应该写的时候

<xsl:variable name="x" select="some/node/path"/>

以后请不要告诉我们您的代码在没有向我们展示您的代码的情况下不起作用。

于 2011-04-13T19:20:13.347 回答