3

我尝试按照有关 Haskell 的网络管道库的教程构建一个简单的客户端-服务器程序。

这是客户端，它同时向服务器发送文件并接收答案：

{-# LANGUAGE OverloadedStrings #-}

import Control.Concurrent.Async (concurrently)
import Data.Functor (void)

import Conduit
import Data.Conduit.Network

main = runTCPClient (clientSettings 4000 "localhost") $ \server ->
    void $ concurrently
        (runConduitRes $ sourceFile "input.txt" .| appSink server)
        (runConduit $ appSource server .| stdoutC)

这是服务器，它计算每个单词的出现次数并将结果发送回客户端：

{-# LANGUAGE OverloadedStrings #-}

import Data.ByteString.Char8 (pack)
import Data.Foldable (toList)
import Data.HashMap.Lazy (empty, insertWith)
import Data.Word8 (isAlphaNum)

import Conduit
import Data.Conduit.Network
import qualified Data.Conduit.Combinators as CC

main = runTCPServer (serverSettings 4000 "*") $ \appData -> do
    hashMap <- runConduit $ appSource appData 
        .| CC.splitOnUnboundedE (not . isAlphaNum)
        .| foldMC insertInHashMap empty
    runConduit $ yield (pack $ show $ toList hashMap)
        .| iterMC print
        .| appSink appData

insertInHashMap x v = do
    return (insertWith (+) v 1 x)

问题是，在我手动关闭客户端之前，服务器不会到达屈服阶段，因此永远不会回答它。我注意到从客户端删除并发并只保留它向服务器发送数据的部分，一切正常。

那么，如何在不中断流程的情况下保留客户端的接收部分？

4

1 回答 1

3

您遇到了死锁：客户端在关闭连接之前正在等待服务器响应，但服务器不知道客户端已完成发送数据并正在等待更多。这基本上是https://cr.yp.to/tcpip/twofd.html中描述的问题：

当generate-data程序结束时，同一个 fd 仍然在consume-data程序中打开，所以内核不知道它应该发送一个 FIN。

在您的情况下，修复需要在客户端进行。一旦通过它发送 input.txt 的内容，您需要在套接字上调用shutdownwith 。ShutdownSendconduit

这是一种方法（我不确定是否有更好的方法）：

{-# LANGUAGE OverloadedStrings #-}

import Control.Concurrent.Async (concurrently)
import Data.Functor (void)
import Data.Foldable (traverse_)

import Conduit
import Data.Conduit.Network

import Data.Streaming.Network (appRawSocket)
import Network.Socket (shutdown, ShutdownCmd(..))

main = runTCPClient (clientSettings 4000 "localhost") $ \server ->
    void $ concurrently
        ((runConduitRes $ sourceFile "input.txt" .| appSink server) >> doneWriting server)
        (runConduit $ appSource server .| stdoutC)

doneWriting = traverse_ (`shutdown` ShutdownSend) . appRawSocket

旁注：在这种情况下，您实际上并不需要客户端中的并发性，因为在您完成写入服务器之前，永远不会从服务器读取任何内容。您可以在写入和关闭后进行读取。

于 2019-05-16T22:57:23.340 回答