7

通常对于 Grails 域或命令类，您声明您的约束并且框架添加一个validate()方法来检查这些约束中的每一个是否对当前实例有效，例如

class Adult {

  String name
  Integer age

  void preValidate() { 
    // Implementation omitted
  }

  static constraints = {
    name(blank: false)
    age(min: 18)
  }
}

def p = new Person(name: 'bob', age: 21)
p.validate()

就我而言，我想确保preValidate始终在验证类之前执行。我可以通过添加一个方法来实现这一点

def customValidate() {
  preValidate()
  validate()
}

但是每个使用这个类的人都需要记住调用customValidate而不是validate. 我也不能这样做

def validate() {
  preValidate()
  super.validate()
}

因为validate不是父类的方法（它是通过元编程添加的）。还有其他方法可以实现我的目标吗？

4

2 回答 2

2

您可以使用 beforeValidate() 事件来实现您的目标。它在1.3.6 发行说明中进行了描述。

于 2011-05-25T14:08:34.393 回答
2

当您的域/命令类具有 preValidate() 方法时，您应该能够通过在元类上使用您自己的 validate 版本来完成此操作。类似于以下代码的BootStrap.groovy内容可能对您有用：

class BootStrap {

    def grailsApplication   // Set via dependency injection

    def init = { servletContext ->

        for (artefactClass in grailsApplication.allArtefacts) {
            def origValidate = artefactClass.metaClass.getMetaMethod('validate', [] as Class[])
            if (!origValidate) {
                continue
            }

            def preValidateMethod = artefactClass.metaClass.getMetaMethod('preValidate', [] as Class[])
            if (!preValidateMethod) {
                continue
            }

            artefactClass.metaClass.validate = {
                preValidateMethod.invoke(delegate)
                origValidate.invoke(delegate)
            }
        }
    }

    def destroy = {
    }
}
于 2011-04-10T22:03:39.520 回答