3

有谁知道如何在 Scheme 中实现 Y 组合器，特别是使用惰性求值和附加参数？据我了解，Scheme (promise?) (delay) 和 (force) 提供惰性评估支持。

我的理解是带有应用程序的 Y-combinator 如下，但是由于应用程序的顺序评估，默认情况下在 Scheme 中不起作用。

((lambda (f)
   ((lambda (x) (f (x x)))
    (lambda (x) (f (x x)))))
 (lambda (r) (r)))

这是一个建议的解决方案（Z-combinator），但是它使用另一个带有参数的 lambda 函数作为解决方案：

;; Z-combinator
(define Z
  (lambda (f)
    ((lambda (g) (f (g g)))
     (lambda (g) (f (lambda args (apply (g g)
                                        args)))))))
;Value: z

((Z (lambda (r)
      (lambda (x)
        (if (< x 2)
            1
            (* x (r (- x 1))))))) 5)
;Value: 120

;; end Z-combinator

基于解决方案的更新

Y-组合器如下：

;; Y-combinator
(define Y
  (lambda (f)
      ((lambda (x) (f (delay (x x))))
       (lambda (x) (f (delay (x x)))))))
;Value: y

;; end Y-combinator

;; Non tail recursive
((Y (lambda (r)
      (lambda (x)
        (if (< x 2)
            1
            (* x ((force r) (- x 1)))))))
   5)
;Value: 120

;; Tail - recursive
((Y (lambda (r)
      (lambda (x acc)
        (if (< x 2)
            acc
            ((force r) (- x 1) (* x acc))))))
   5 1)

;Value: 120

感谢您的指导！

4

2 回答 2

2

是的，通过严格评估，自我应用程序 (xx) 会导致发生无限循环。如果您延迟此操作，您可以使用 y-combinator，只要您还在其使用站点“强制”该延迟对象：

(define (test)
  (((lambda (f)
      ((lambda (x) (f (delay (x x))))
       (lambda (x) (f (delay (x x))))))
    (lambda (r)
      (lambda (x)
        (if (< x 2)
            1
            (* x ((force r) (- x 1)))))))
   5))

对在严格设置下工作的 y-combinator 进行变体的正常方法是 eta-expand 自我应用，这是另一种延迟它的方法，但不需要显式施加力。相反，强制是由功能应用程序完成的。

于 2019-05-04T09:33:54.570 回答
2

正常顺序 Y 组合器，这里(ack 3 6)在 Lazy Racket 中计算：

#lang lazy

(define Y
  (lambda (f)
    ((lambda (g) (g g))
     (lambda (g) (f (g g))))))

((Y (lambda (ackermann)
      (lambda (m n)
        (cond
        ((= m 0) (+ n 1))
        ((= n 0) (ackermann (- m 1) 1))
        (else (ackermann (- m 1) (ackermann m (- n 1))))))))
 3
 6) ; ==> 509

Scheme 不像 Lazy Racket 那样是一种惰性语言，因此 Y 需要有所不同。它现在被称为 Z 组合器：

#!r6rs
(import (rnrs base))

(define Z
  (lambda (f)
    ((lambda (g)
       (f (g g)))
     (lambda (g)
       (f (lambda args (apply (g g) args)))))))

((Z (lambda (ackermann)
      (lambda (m n)
        (cond
        ((= m 0) (+ n 1))
        ((= n 0) (ackermann (- m 1) 1))
        (else (ackermann (- m 1) (ackermann m (- n 1))))))))
 3
 6) ; ==> 509

使用delayandforce并没有真正让它变得更好：

#!r6rs
(import (rnrs base)
        (rnrs r5rs))

(define DY
  (lambda (f)
    ((lambda (g) (g g))
     (lambda (g) (f (delay (g g)))))))


((DY (lambda (d-ackermann)
      (lambda (m n)
        (cond
          ((= m 0) (+ n 1))
          ((= n 0) ((force d-ackermann) (- m 1) 1))
          (else ((force d-ackermann) (- m 1) ((force d-ackermann) m (- n 1))))))))
 3
 6) ; ==> 509

通常Y并Z允许我们命名我们的递归过程，但在最后一个中，我们得到了一个我们需要解决的承诺，因此我们泄露了实现细节并且它变得更加难以使用。通常当涉及到 Promise 时，我们希望避免不必要的执行，但是调用应该返回一个 Promise。

于 2019-05-04T22:35:59.253 回答