6

我有一些 JSON 存储在数据库列中，如下所示：

pokeapi=# SELECT height FROM pokeapi_pokedex WHERE species = 'Ninetales';
-[ RECORD 1 ]------------------------------------------
height | {"default": {"feet": "6'07\"", "meters": 2.0}}

作为我正在研究的“生成”算法的一部分，我想将此值放入 %hash 中，将其乘以(0.9..1.1).rand（允许高度的“自然 10% 变化”），然后创建一个新的 %散列在相同的结构中。我的select-height方法如下所示：

method select-height(:$species, :$form = 'default') {
    my %heights = $.data-source.get-height(:$species, :$form);

    my %height = %heights * (0.9..1.1).rand;

    say %height;
}

这实际上要求我get-height获得该物种的“平均”高度（公制和英制）。

method get-height (:$species, :$form) {
    my $query = dbh.prepare(qq:to/STATEMENT/);
           SELECT height FROM pokeapi_pokedex WHERE species = ?;
        STATEMENT

    $query.execute($species);

    my %height = from-json($query.row);
    my %heights = self.values-or-defaults(%height, $form);

    return %heights;
}

但是，我在执行时收到以下错误（我假设是因为我试图将散列作为一个整体而不是散列的单个元素）：

$ perl6 -I lib/ examples/height-weight.p6
{feet => 6'07", meters => 2}
Odd number of elements found where hash initializer expected:
Only saw: 1.8693857987465123e0
  in method select-height at /home/kane/Projects/kawaii/p6-pokeapi/lib/Pokeapi/Pokemon/Generator.pm6 (Pokeapi::Pokemon::Generator) line 22
  in block <unit> at examples/height-weight.p6 line 7

是否有一种更简单（且有效）的方法可以在不为每个元素复制我的代码的情况下执行此操作？:)

4

2 回答 2

6

首先，您的代码逻辑存在问题。最初，你得到一个值的哈希值，"feet": "6'07\"", "meters": 2.0从 json 中解析出来，它meters是一个数字和feet一个字符串。接下来，您尝试将它乘以一个随机值......虽然它适用于数字，但不适用于字符串。Perl 6 的同种异形实际上允许您这样做：say "5" * 3将 return 15，但X"Y'模式足够复杂，Perl 6 无法自然地理解它。

因此，您可能需要在处理之前对其进行转换，然后再将其转换回来。

第二件事是导致您观察到的错误的确切线。

考虑一下：

my %a = a => 5;
%a = %a * 10 => 5; # %a becomes a hash with a single value of 10 => 5
# It happens because when a Hash is used in math ops, its size is used as a value
# Thus, if you have a single value, it'll become 1 * 10, thus 10
# And for %a = a => 1, b => 2; %a * 5 will be evaluated to 10
%a = %a * 10; # error, the key is passed, but not a value

要直接处理哈希值，您需要使用map方法并处理每一对，例如：%a .= map({ .key => .value * (0.9..1.1).rand }).

当然，它可以打高尔夫球或以其他方式编写，但主要问题是这样解决的。

于 2019-04-18T16:52:40.417 回答
5

您已接受@Takao 的回答。该解决方案需要手动挖掘%hash以获取叶哈希/列表，然后应用map.

鉴于您的问题的标题提到“返回......相同的 结构”并且正文包括看起来像嵌套结构的东西，我认为重要的是有一个答案提供一些惯用的解决方案，用于自动下降和复制嵌套结构：

my %hash = :a{:b{:c,:d}}

say my %new-hash = %hash».&{ (0.9 .. 1.1) .rand }
# {a => {b => {c => 1.0476391741359872, d => 0.963626602773474}}}

# Update leaf values of original `%hash` in-place:
%hash».&{ $_ = (0.9 .. 1.1) .rand }

# Same effect:
%hash »*=» (0.9..1.1).rand;

# Same effect:
%hash.deepmap: { $_ = (0.9..1.1).rand }

Hyperops（例如»）迭代一个或两个数据结构以到达它们的叶子，然后应用被超化的操作：

say %hash».++ # in-place increment leaf values of `%hash` even if nested

.&{ ... }使用方法调用语法在大括号中调用闭包。将其与超运算结合起来可以编写：

%hash».&{ $_ = (0.9 .. 1.1) .rand }

另一种选择是.deepmap：

%hash.deepmap: { $_ = (0.9..1.1).rand }

hyperops 和 deepmap 之间的一个关键区别是允许编译器迭代数据结构并以任何顺序并行运行超操作，而deepmap迭代总是按顺序发生。

于 2019-04-18T21:20:50.117 回答